Formule excel pour calcul de la nouvelle indemnite de licencieme

Fermé

Stel27 Messages postés 1 Date d'inscription mercredi 8 novembre 2017 Statut Membre Dernière intervention 8 novembre 2017 - 8 nov. 2017 à 12:30
mdo100 Messages postés 126 Date d'inscription jeudi 9 décembre 2010 Statut Membre Dernière intervention 21 février 2019 - 9 nov. 2017 à 19:42

Bonjour,

Je n'arrive pas à faire une formule sur excel pour le nouveau calcul de l'indemnité légale de licenciement .
Lorsque le salarié est en année plaine, la formule fonctionne bien mais lorsque l'année est incomplète la formule ne fonctionne plus.
Sachant que la formule de calcul est:

1/4 de mois de salaire par année d'ancienneté pour les 10 premières années +1/4 de mois de salaire * x/12

1/3 de mois de salaire par année d'ancienneté à partir de la 11ème année + 1/3 de mois de salaire * x/12 (x étant le nombre de mois).

j'ai fait la formule suivante: =(((salaire*années<=10)/4)+((salaire*mois)/(4/12))+((salaire*années > 10ans ) /3)+(salaire*mois)/(3/12)).

Merci pour l'aide que vous pourrez m'apporter

A voir également:

Tableau excel calcul indemnité licenciement inaptitude
Tableau croisé dynamique - Guide
Liste déroulante excel - Guide
Calcul moyenne excel - Guide
Tableau ascii - Guide
Formule excel - Guide

2 réponses

Réponse 1 / 2

gbinforme Messages postés 14946 Date d'inscription lundi 18 octobre 2004 Statut Contributeur Dernière intervention 24 juin 2020 4 684
8 nov. 2017 à 13:58

Bonjour,

Avec ton salaire en A2 et la date d'embauche en B2, je te propose cette formule qui doit pouvoir être simplifiée d'ailleurs.

=MIN(DATEDIF(B2;AUJOURDHUI();"m");120)*0,25*A2+SI(DATEDIF(B2;AUJOURDHUI();"m")>120;(DATEDIF(B2;AUJOURDHUI();"m")-120)*0,33*A2;0)

eriiic Messages postés 24570 Date d'inscription mardi 11 septembre 2007 Statut Contributeur Dernière intervention 23 avril 2024 7 213
Modifié le 8 nov. 2017 à 18:50

Bonjour,

une simplification en effet :

=A2*(MIN(120;DATEDIF(B2;AUJOURDHUI();"m"))/4+MAX(0;DATEDIF(B2;AUJOURDHUI();"m")-120)/3)

attention, le *0.33 au lieu de /3 désavantage le salarié.
eric

gbinforme Messages postés 14946 Date d'inscription lundi 18 octobre 2004 Statut Contributeur Dernière intervention 24 juin 2020 4 684
8 nov. 2017 à 18:56

Salut Éric,

Bien vu, cela supprime le test et c'est plus net.

Réponse 2 / 2

mdo100 Messages postés 126 Date d'inscription jeudi 9 décembre 2010 Statut Membre Dernière intervention 21 février 2019 22
9 nov. 2017 à 13:05

Bonjour Stel27, gbinforme, eriiic,

Selon les articles 39 et 40 de l’ordonnance n° 2017-1387 et de ce que j'en ai compris.

Il y a 3 régimes depuis septembre 2017 d'indemnité légale de licenciement.

Concernant le licenciement pour motif personnel, économique ou inaptitude d’origine non professionnelle et impossibilité de reclassement : Il y a un plancher de 8 mois et un plafond de 240 mois.

D'où cette formule avec date en "A2" et salaire moyen en "B2".
Résultat en "C2":

=SI(DATEDIF($A2;AUJOURDHUI();"m")>240;0,25*B2*MIN(10;DATEDIF($A2;AUJOURDHUI();"y"))+1/3*B2*(DATEDIF($A2;AUJOURDHUI();"y")-MIN(10;DATEDIF($A2;AUJOURDHUI();"y")));SI(ET(DATEDIF($A2;AUJOURDHUI();"y")<1;DATEDIF($A2;AUJOURDHUI();"ym")<8);0;SI(DATEDIF(A2;AUJOURDHUI();"y")>10;0,25*B2*MIN(10;DATEDIF($A2;AUJOURDHUI();"y"))+1/3*B2*(DATEDIF($A2;AUJOURDHUI();"y")-MIN(10;DATEDIF($A2;AUJOURDHUI();"y")))+0,25*B2*DATEDIF($A2;AUJOURDHUI();"ym")/12;0,25*B2*DATEDIF($A2;AUJOURDHUI();"y")+0,25*B2*DATEDIF($A2;AUJOURDHUI();"ym")/12)))

J'imagine que vous allez hurler en voyant cette formule à rallonge, pourtant elle me semble juste et je ne doute pas quelle puisse être raccourcie.

Voir les différents cas de figure dans le fichier joint.
http://www.cjoint.com/c/GKjl4goA0Eu

Cordialement.

gbinforme Messages postés 14946 Date d'inscription lundi 18 octobre 2004 Statut Contributeur Dernière intervention 24 juin 2020 4 684
Modifié le 9 nov. 2017 à 18:59

Bonsoir,

J'imagine que vous allez hurler en voyant cette formule à rallonge,... et je ne doute pas quelle puisse être raccourcie

Tu as bien imaginé ! Ta formule roman ne sert pas à grand chose car celle d'Éric corrigée au désavantage du salarié que j'avais très enrichi donne exactement le même résultat :

=B2*(MIN(120;DATEDIF(A2;AUJOURDHUI();"m"))/4+MAX(0;DATEDIF(A2;AUJOURDHUI();"m")-120)/3)/12

Pour quoi faire simple si l'on passer beaucoup de temps à complexifier ! ;-)

Si tu vérifies les exemples donnés par service-public tu verras que la formule simple est plus juste pour le second.

mdo100 Messages postés 126 Date d'inscription jeudi 9 décembre 2010 Statut Membre Dernière intervention 21 février 2019 22 > gbinforme Messages postés 14946 Date d'inscription lundi 18 octobre 2004 Statut Contributeur Dernière intervention 24 juin 2020
9 nov. 2017 à 19:42

Re gbinforme,

Pour quoi faire simple si l'on passer beaucoup de temps à complexifier ! ;-)

Parce que je n'ai pas ton talent ;~) toutefois tu ne tiens pas compte du plancher de 8 mois et du plafond de 240 mois.

Cela donnerait ceci en "C2" en tenant compte de ta modif:

=SI(DATEDIF(A2;AUJOURDHUI();"m")<8;0;SI(DATEDIF(A2;AUJOURDHUI();"m")>240;0,25*B2*MIN(10;DATEDIF($A2;AUJOURDHUI();"y"))+1/3*B2*(DATEDIF($A2;AUJOURDHUI();"y")-MIN(10;DATEDIF($A2;AUJOURDHUI();"y")));B2*(MIN(120;DATEDIF(A2;AUJOURDHUI();"m"))/4+MAX(0;DATEDIF(A2;AUJOURDHUI();"m")-120)/3)/12))

Penses-tu pouvoir raccourcir plus ?

Cordialement.

Discussions similaires

EXCEL CALCUL INDEMNITE DE LICENCIEMENT

formules excel pour calcul indemnités nounou

Calcul indemnité de licenciement

calcule indémnité licenciement

Calcul ancienneté

LICENCIEMENT POUR INAPTITUDE

Discussions similaires

Newsletters