Probleme formule

Function evalParamFormule(formule As Range, Optional nbSignificatifs As Long = 6, Optional ing As Boolean = False)
    ' évalue certains paramètres de la formule
    ' ceux dont la référence appartient à une plage dont le nom commence par ev_ sont évalués
    ' ces plages doivent être limitées aux colonnes A:Z
    ' Paramètres optionnels
    ' nbSignificatifs: nombre de chiffres significatifs à afficher
    ' ing: affichage au format ingénieur (exposant multiple de 3)

    Dim a19 As String, fEval As String, param As Variant, a
    Dim pl As Range, pl2 As Range, nom As Name, i As Long
    Dim Exposant As Long, Parts() As String, valeur As String

    fEval = formule.Formula
    a19 = formule.Formula
    If Left(a19, 1) <> "=" Then
        evalParamFormule = CVErr(xlErrValue)
        Exit Function
    End If
    a19 = Mid(a19, 2)
    a19 = Replace(Replace(Replace(Replace(Replace(Replace(a19, "+", "µ"), "-", "µ"), "*", "µ"), "/", "µ"), "(", "µ"), ")", "µ")
    ' découpage de la formule sur +, -, *, /, (, et ) pour récup des paramètres
    param = Split(a19, "µ")
    For i = 0 To UBound(param)
        'pour chaque paramètre
        Set pl = Nothing
        On Error Resume Next
        Set pl = Range(param(i))
        On Error GoTo 0
        If Not pl Is Nothing Then
            ' si le paramètre est une référence
            For Each nom In Names
                'pour chaque nom
                If Left(nom.Name, 3) = "ev_" Then
                    ' si le nom commence par ev_
                    Set pl2 = Intersect(Range(nom), pl)
                    If Not pl2 Is Nothing Then
                        If Intersect(Range(nom), pl).Count = pl.Count Then
                            'et que le paramètre intégralement est inclus dans le nom
                            Parts = Split(Format(Range(param(i)).Value, "0.0#############E+0"), "E")
                            Exposant = 3 * Int(Parts(1) / 3)
                            valeur = Round(Parts(0), nbSignificatifs - 1) * 10 ^ (Parts(1) - Exposant)
                            If ing Then
                                valeur = valeur & IIf(Exposant, "E" & Exposant, "")
                            Else
                                valeur = CDbl(valeur & "E" & Exposant)
                            End If
                            fEval = Replace(fEval, param(i), valeur)
                        End If
                    End If
                End If
            Next nom
        End If
    Next i
    evalParamFormule = Replace(fEval, "+-", "-")
End Function