Verifier si une variable appartient à un ensemble de valeurs [Résolu]

Réponse 2 / 10

panda
10 juin 2013 à 15:42

bon du coup ca donnerait:

Function testchoix(Tabl As String, quoi As Integer) As Boolean

montab = Array(Tabl)
trouve = False
For i = LBound(montab) To UBound(montab)
If quoi = montab(i) Then trouve = True
Next

End Function

et pour tester:

ouinon = testchoix("(1,3,5,7,9,11,13,15)", Var)
If ouinon = True Then
.....

mais ça n'a pas l'air de fonctionner, ma condition if est toujours fausse

Réponse 3 / 10

panda
10 juin 2013 à 14:25

je cherchais en utilisant la fonction array, mais sans succès:

firstarray = Array(8, 9, 10, 11, 12, 13, 14, 15)
myarray = Filter(firstarray, Var)
If UBound(myarray) > 0 Then

ça bloque à "myarray = Filter(firstarray, nomod)". j'ai essayé "myarray = Filter(firstarray, Var, true)" mais dans tous les cas il me dit que je n'ai pas le bon nombre d'arguments.

une idée?

Réponse 4 / 10

panda
10 juin 2013 à 14:34

j'ai une autre piste avec ce code trouvé sur un site:

Sub essai()
montableau = Array("A", "B", "C", "D")
x = "C"
p = Application.Match(x, montableau, 0)
If IsError(p) Then
MsgBox x & " Inconnu"
Else
MsgBox p
End If
End Sub

mais mon VBA (pour access) ne semble pas connaitre la méthode Match

Vous n’avez pas trouvé la réponse que vous recherchez ?

Posez votre question

Réponse 5 / 10

panda
10 juin 2013 à 15:20

merci pour ta réponse.
comme ça, ça doit fonctionner effectivement.
ce qui est dommage c'est que je voulais une instruction la plus courte possible pour faire un simple

if Var appartient à {x,y,z} then

et rendre le code le plus lisible possible.
mais ça fera très bien faute de mieux.
je reste étonné qu'il n'y ai pas plus concis

Réponse 6 / 10

panda
10 juin 2013 à 15:24

pas mal l'idée du dictionnaire, je connaissais pas. c'est un peu l'idée que j'avais, tester l'existence de ma variable dans un ensemble, là c'est dans un dictionnaire.

Réponse 7 / 10

Patrice33740 Messages postés 8556 Date d'inscription dimanche 13 juin 2010 Statut Membre Dernière intervention 2 mars 2023 1 775
10 juin 2013 à 15:51

Re,
«ce qui est dommage c'est que je voulais une instruction la plus courte possible pour faire un simple
if Var appartient à {x,y,z} then
et rendre le code le plus lisible possible»

Voici :

Sub test()
Dim var As Integer
  var = 12
  If Appartient(var, "8, 9, 10, 12, 14, 15") Then
    MsgBox var & " existe"
  Else
    MsgBox var & " inconnu"
  End If
End Sub

Private Function Appartient(var As Variant, liste As String) As Boolean
  Select Case CStr(var)
    Case liste
      Appartient = True
    Case Else
      Appartient = False
  End Select
End Function

Réponse 8 / 10

Yoda
10 juin 2013 à 14:51

Bonjour,

Il faut passer tout le tableau en revue dans une boucle pour savoir si un élément existe.

Sub essai() 
montableau = Array("A", "B", "C", "D") 
x = "C"
trouve=False
For i = LBound(montableau) To UBound(montableau)
   if x=montableau(i) then trouve=True
next
if trouve then
   MsgBox x  & " Connu"
else
   MsgBox x  & " Inconnu"
endif
End Sub

Le plus pratique serait de faire une fonction personnalisée.

A+.

Réponse 9 / 10

Patrice33740 Messages postés 8556 Date d'inscription dimanche 13 juin 2010 Statut Membre Dernière intervention 2 mars 2023 1 775
10 juin 2013 à 15:12

Bonjour,

Pour éviter la boucle, tu peux utiliser un dictionnaire :

Option Explicit
Sub Test1()
Dim d As Object
Dim x As String
  'Variable à trouver
  x = "C"
  'Création d'un dictionnaire
  Set d = CreateObject("Scripting.Dictionary")
  'Ajout des clés, valeurs
  d.Add "A", ""
  d.Add "B", ""
  d.Add "C", ""
  d.Add "D", ""
  'Test
  If d.Exists(x) Then
    MsgBox x & " existe"
  Else
    MsgBox x & " inconnu"
  End If
End Sub

Le même avec une référence à Microsoft Scripting Runtime :

Sub Test2()
' Ajouter une référence à Microsoft Scripting Runtime
Dim d As Scripting.Dictionary
Dim x As String
  'Variable à trouver
  x = "C"
  'Création d'un dictionnaire
  Set d = New Dictionary
  'Ajout des clés, valeurs
  d.Add "A", ""
  d.Add "B", ""
  d.Add "C", ""
  d.Add "D", ""
  'Test
  If d.Exists(x) Then
    MsgBox x & " existe"
  Else
    MsgBox x & " inconnu"
  End If
End Sub

Patrice33740 Messages postés 8556 Date d'inscription dimanche 13 juin 2010 Statut Membre Dernière intervention 2 mars 2023 1 775
10 juin 2013 à 15:22

PS, ton idée de filtre fonctionne aussi :

Sub t()
Dim firstarray as Variant
Dim myarray as Variant
Dim var As Integer
  var = 13
  firstarray = Array(8, 9, 10, 11, 12, 13, 14, 15)
  myarray = Filter(firstarray, var)
  If UBound(myarray) > -1 Then
    MsgBox var & " existe"
  Else
    MsgBox var & " inconnu"
  End If
End Sub

panda
10 juin 2013 à 16:05

je ne vois pas de différence entre ton code et le mien si ce n'est le "> -1" au lieu du ">0"
or VBA bloque sur l'instruction d'avant, " myarray = Filter(firstarray, var)" .
il me dit "Nombre d'arguments incorrect ou affectation de propriété incorrecte"

Patrice33740 Messages postés 8556 Date d'inscription dimanche 13 juin 2010 Statut Membre Dernière intervention 2 mars 2023 1 775
10 juin 2013 à 16:22

Chez moi çà fonctionne (sous Acces 2007 et sous Excel 2003 et 2007 versions françaises)
Peut-être un problème de version ou de déclaration des variables ?
Commences le module par Option Explicit et déclares toutes les variables.

Patrice

panda
10 juin 2013 à 16:28

je vais vérifier mes variables.
je suis sous access 2010 c'est peut être ça.

panda
11 juin 2013 à 11:12

décidément je ne vois pas, j'ai pourtant retourné ça dans tous les sens.
mon code :

Dim nomod As String
Dim firstarray As Variant, myarray As Variant

firstarray = Array(8, 9, 10, 11, 12, 13, 14, 15)
For i = LBound(firstarray) To UBound(firstarray)
MsgBox firstarray(i)
Next i
myarray = Filter(firstarray, nomod)
If UBound(myarray) > -1 Then
.....

la boucle ne sert qu'a m'assurer que mon tableau firstarray est bien fait, et c'est le cas.
pourtant l'instruction "myarray = Filter(firstarray, nomod)" renvoie toujours le même message d'erreur: "erreur de compilation : nombre d'arguments incorrect ou affectation de propriété incorrecte"
j'ai tout essayé, remplacer ma variable par une string quelconque....

j'aime pas rester sur un échec, une idée?

Réponse 10 / 10

Yoda
10 juin 2013 à 15:34

Comme je le disais, on peut programmer une fonction pesonnalisée, du coup ça devient très simple et lisible, par exemple:

La fonction

Function Existe(table, elem) As Boolean
Existe = False
For i = LBound(table) To UBound(table)
   If table(i) = elem Then Existe = True
Next
End Function

Appel à la fonction

Sub essai()
A1 = Array(8, 9, 10, 11, 12, 13, 14, 15)
var=10
If Existe(A1, var) then
   MsgBox var & " existe"
  Else
    MsgBox var & " inconnu"
 End If

var="X"
S1 = Array("A", "B", "C", "D", "E")
If Existe(S1, var) then
   MsgBox var & " existe"
  Else
    MsgBox var & " inconnu"
 End If

End Sub

telliak Messages postés 3655 Date d'inscription mercredi 20 septembre 2006 Statut Membre Dernière intervention 27 mars 2024 874
Modifié par telliak le 10/06/2013 à 15:39

Pourquoi faire simple quand on peut faire compliqué...

panda
10 juin 2013 à 16:19

pas mal comme ça.
merci beaucoup

Verifier si une variable appartient à un ensemble de valeurs

10 réponses

Discussions similaires

Newsletters