Envoi email automatique code VBA Outlook

Bonjour,

effectivement Morgothal t'a donné une bonne adresse pour l'envoi de message sans client de messagerie, avec ou sans pièce jointe et corps de texte et sans avoir besoin de cocher de référence dans VBA.

Voici le code que j'utilise :

 Sub SendMail()      

    Dim iMsg As Object, iConf As Object, Flds As Object      
    Dim texte As String 'déclaration variable texte pour le corps du message      
          
    'texte avec balise CSS pour la mise en forme puisque le corps du message est en html      
    texte = "<SPAN STYLE=background-color:white;font-size:12pt;font-family:Times New Roman>Bonjour,</SPAN><BR><BR>"      
    texte = texte & "<B><SPAN STYLE=background-color:white;font-size:18pt;font-family:arial>Essai</SPAN></B><BR><BR>"      
          
    Set iMsg = CreateObject("cdo.message")      
    Set iConf = CreateObject("cdo.configuration")      
    Set Flds = iConf.Fields      
    With Flds      
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2      
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "" 'adresse du serveur smtp (https://www.commentcamarche.net/faq/893-parametres-de-serveurs-pop-imap-et-smtp-des-principaux-fai      
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465 'tester 25, 465 ou 587      
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True  'Utilise une connection SSL (True or False)      
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60      
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 '0 : pas d'authentification, 1 : authentification basique      
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "identifiant" 'identifiant de messagerie      
        .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "mot de passe" 'mot de passe de messagerie      
        .Update      
    End With      

    With iMsg      
        Set .Configuration = iConf      
        .From = "" 'adresse expéditeur      
        .To = "" 'adresse destinataire      
        .CC "" 'adresse destinataire en copie      
        .BCC = "" ' adresse destinataire en copie cachée      
        .Subject = "Envoi mail excel vba" 'sujet du message      
        .HTMLBody = texte 'variable texte (voir plus haut) = corps du message      
        .AddAttachment ("C:\Users....") 'ajout de pièce jointe 1      
        .AddAttachment ("C:\Users....") 'ajout de pièce jointe 2      
        .AddAttachment ("C:\Users....") 'ajout de pièce jointe 3. A répéter autant de fois que nécessaire dans la limite autorisé en Mo.      
        .Fields("urn:schemas:mailheader:disposition-notification-to") = "" 'adresse pour recevoir une notification de distribution.  En général c'est l'adresse de l'expéditeur.      
        .Fields("urn:schemas:mailheader:return-receipt-to") = "" 'adresse pour recevoir un accusé de réception. En général c'est l'adresse de l'expéditeur.      
        .Send      
    End With      
          
    End Sub      

Va voir à cette adresse pour la configuration, en fonction de ton fournisseur d'accès internet (FAI) :

 https://www.commentcamarche.net/faq/893-parametres-de-serveurs-pop-imap-et-smtp-des-principaux-fai    

Par contre avec le code actuel tu n'as pas de trace du message envoyé. Une solution simple consiste à te mettre en copie cachée.

Bien cordialement,