Bonsoir,

cette fonction te renvoie 'true" si le classeur est ouvert

Function FichOuvert(F As String) As Boolean
'Auteur: Didier_mdf (merci) site INCONTOURNABLE :http://www.mdf-xlpages.com/
Dim Wk As Workbook
On Error Resume Next
Set Wk = Workbooks(F)
On Error GoTo 0
FichOuvert = Not Wk Is Nothing
End Function

F est le fullname du classeur
Cordialement, Michel

Bonsoir et merci beaucoup pour votre suggestion. Malheureusement le problème reste! Je dois passer le nom du fichier en variable et cela empêche la macro de fonctionner. De plus la fonction regarde sur "mes" classeur pour voir s'ils sont ouvert alors que, l'utilisateur qui pourrait avoir ouvert le fichier, n'est pas sur le même ordi!

Merci quand même

*****************
J'ai, entretemps, trouvé un bout de fonction

Private Function EstDansCollection(Coln As Object, Item As String) As Boolean
Dim obj As Object
On Error Resume Next
Set obj = Coln(Item)
EstDansCollection = Not obj Is Nothing
End Function

mais le problème ici est que la valeur qui passe la fontion doit être en claire et pas sous forme de variable!

Merci à tous.

J'attends vos lumières

Bonjour,

Trouvé chez Frederic SIgonneau
http://frederic.sigonneau.free.fr/code/Fichiers/DetruireTous­FichiersDossier.txt

Function IsFileOpen(filename As String)
'auteur inconnu, mpep
Dim filenum As Integer, errnum As Integer

  On Error Resume Next   ' Turn error checking off.
  filenum = FreeFile()   ' Get a free file number.
  ' Attempt to open the file and lock it.
  Open filename For Input Lock Read As #filenum
  Close filenum          ' Close the file.
  errnum = Err           ' Save the error number that occurred.
  On Error GoTo 0        ' Turn error checking back on.

  ' Check to see which error occurred.
  Select Case errnum
           
    ' No error occurred.
    ' File is NOT already open by another user.
    Case 0
      IsFileOpen = False

    ' Error number for "Permission Denied."
    ' File is already opened by another user.
    Case 70
      IsFileOpen = True

    ' Another error occurred, file is being queried.
    Case Else
      Error errnum
  End Select

End Function