Comment gérer les doublons sur deux colonnes VBA

Option Explicit

Const coCod = "A"   ' colonne code
Const coSta = "D"   ' colonne statut
Const lideb = 2     ' premiere ligne des données
Const vert = 50     ' code couleur
Const rouge = 3     ' idem

Private Sub btOK_Click()
Dim li As Long, lifin As Long, cod As Long, sta As String, lili As Long
Dim obj As Object, plage As Range
' inhibe la maj de la feuille après chaque modification
Application.ScreenUpdating = False
' derniere ligne non vide de la colone cocod
lifin = Range(coCod & Rows.Count).End(xlUp).Row
' boucle sur les lignes en partant de la dernière (à cause des suppressions eventuelles de lignes
For li = lifin To lideb + 2 Step -1
  ' plage où on va rechercher le code cod
  Set plage = Range(coCod & lideb & ":" & coCod & li - 1)
  ' code et statut ligne i
  cod = Range(coCod & li).Value
  sta = Range(coSta & li).Value
  ' recherche cod dans plage
  Set obj = plage.Find(cod, , , xlWhole)
  ' si cod est trouvé
  If Not obj Is Nothing Then
    ' on recupere sa ligne
    lili = obj.Row
    ' si le statut ligne lili = statut ligne i alors on supprime la ligne li
    If Range(coSta & lili).Value = sta Then
      Rows(li).Delete
    ' sinon on met en rouge la ligne lili et en vert la ligne li
    Else
      Range(coCod & lili & ":" & coSta & lili).Font.ColorIndex = rouge
      Range(coCod & li & ":" & coSta & li).Font.ColorIndex = vert
    End If
  End If
Next li
' activation de la maj de la feuille
Application.ScreenUpdating = True
End Sub