Comment trouver la première valeur différente d'une colonne?

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim NL As Integer 'déclare la variable NL (Nombre de Lignes)
Dim NC As Byte 'déclare la variable NC (Nombre de Colonnes)
Dim I As Integer 'déclare la variable I (Incrément)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim TMP As Variant 'déclare la variable TMP (TeMPoraire)
Dim A As Integer 'déclare la variable A (Année)
Dim OA As Worksheet 'déclare la variable OA (Onglet Année)
Dim J As Byte 'déclare la variable J (incrément)
Dim TL() As Variant 'déclare la variable TL (Tableau des Lignes)

Set O = Sheets(1) 'définit l'onglet O
TV = O.Range("A2").CurrentRegion 'définit le tableau des valeurs TV
NL = UBound(TV, 1) 'définit le nombre de ligne NL du tableau des valeurs TV
NC = UBound(TV, 2) 'définit le nombre de colonnes NC du tableau des valeurs TV
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For I = 2 To NL 'boucle sur toutes les lignes I du tableau des valeurs TV (en partant de la seconde)
    D(TV(I, 2)) = "" 'alimente le dictionnaire D avec les éléments de la colonne 2 (années) du tableau des valeurs TV
Next I 'prochaine ligne de la boucle
TMP = D.Keys 'récupère dans le tableau temporaire TMP la liste des éléments du dictionnaire D sans doublon
For A = 0 To UBound(TMP) 'boucle 1 : sur toutes les années A du tableau TMP
    On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
    Set OA = Worksheets(TMP(A)) 'définit l'onglet OA (génère une erreur si cet onglet n'existe pas)
    If Err <> 0 Then 'condition : si une erreur a été générée
        Err.Clear 'supprime l'erreur
        Sheets.Add after:=Sheets(Sheets.Count) 'ajoute un onglet vierge en dernière position
        ActiveSheet.Name = TMP(A) 'renomme l'onglet
        Set OA = ActiveSheet 'définit l'onglet OA
    End If 'fin de la condition
    On Error GoTo 0 'annule la gestion des erreurs
    K = 1 'initialise la variable K
    For I = 2 To NL 'boucle 2 : sur toutes les lignes I du tableau des valeur TV (en partant de la seconde)
        If TV(I, 2) = TMP(A) Then 'condition : si la donnée ligne I colonne 2 de TV est égale à l'année TMP(A)
            'redimensionne le tableau des lignes TL (autant de lignes que TV a de colonnes, K colonnes)
            ReDim Preserve TL(1 To NC, 1 To K)
            For J = 1 To NC 'boucle 3 : sur toutes les colonnes J de TV
                TL(J, K) = TV(I, J) 'récupère dans la ligne J de TL la valeur de la colonne J de TV (=transposition)
            Next J 'prochaine colonne de la boucle 3
            K = K + 1 'incrémente K (ajoute une colonne au tableau des lignes TL)
        End If 'fin de la condition
    Next I 'prochaine ligne de la boucle 2
    If K > 1 Then 'condition : si K est supérieure à un (ou moins une occurrence trouvée)
        'renvoie la première ligne de TV dans A1 redimensionnée
        OA.Range("A1").Resize(1, NC) = Application.Index(TV, 1)
        'renvoi dans A2 redimensionnée le tableau TL transposé
        OA.Range("A2").Resize(UBound(TL, 2), UBound(TL, 1)).Value = Application.Transpose(TL)
        Erase TL 'efface le tableau TL
    End If 'fin de la condition
Next A 'prochaine année de la boucle 1
End Sub

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim PL As Range 'déclare la variable PL (PLage)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim I As Integer 'déclare la variable I (Incrément)
Dim TMP As Variant 'déclare la variable TMP (TeMPoraire)
Dim A As Integer 'déclare la variable A (Année)
Dim OA As Worksheet 'déclare la variable OA (Onglet Année)
Dim PLV As Range 'déclare la variable PLV (PLage Visible)

Set O = Sheets(1) 'définit l'onglet O
Set PL = O.Range("A1").CurrentRegion 'définit la plage PL
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For I = 2 To PL.Rows.Count 'boucle sur toutes les lignes I de la plage PL (en partant de la seconde)
    D(O.Cells(I, 2).Value) = "" 'alimente le dictionnaire D avec les éléments de la colonne 2 (années) de la plage PL
Next I 'prochaine ligne de la boucle
TMP = D.Keys 'récupère dans le tableau temporaire TMP la liste des éléments du dictionnaire D sans doublon
For A = 0 To UBound(TMP) 'boucle 1 : sur toutes les années A du tableau TMP
    On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
    Set OA = Worksheets(TMP(A)) 'définit l'onglet OA (génère une erreur si cet onglet n'existe pas)
    If Err <> 0 Then 'condition : si une erreur a été générée
        Err.Clear 'supprime l'erreur
        Sheets.Add after:=Sheets(Sheets.Count) 'ajoute un onglet vierge en dernière position
        ActiveSheet.Name = TMP(A) 'renomme l'onglet
        Set OA = ActiveSheet 'définit l'onglet OA
    End If 'fin de la condition
    PL.AutoFilter Field:=2, Criteria1:=TMP(A)
    Set PLV = PL.SpecialCells(xlCellTypeVisible) 'définit la plage PLV (cellules visibles de la plage PL)
    PLV.Copy OA.Range("A1") 'copy la plage PLV dans la cellule A1 de l'onglet OA
    PL.AutoFilter 'supprime le filtre automatique
    On Error GoTo 0 'annule la gestion des erreurs
Next A 'prochaine année de la boucle 1
End Sub