Mettre en place un macro qui va me generer un fichier txt

Salut,

Toutes ces fonctions que j'utilise (Len, Left, Replace, Split), et bien d'autres, sont expliquées ICI.

    'traitement colonne B
'ICI on stocke la valeur comprise entre les deux premiers  |, donc la colonne B
'cette variable ColBInit sert à la fonction Replace. En effet, il faut savoir quoi remplacer...
    ColBInit = Split(Entete, " |")(1)
'ColB est la variable dont nous allons modifier la valeur pour obtenir le résultat voulu.
'Au départ ColB est égal à ColBInit
    ColB = ColBInit
'On veut 8 caractères dans la colonne B, donc on boucle tant que notre variable n'a pas 8 caractères
    Do While Len(ColB) < 8
'on ajoute des 0 avant
      ColB = "0" & ColB
    Loop
'on remplace, dans notre entête, la valeur initiale : ColBInit par ColB.
    Entete = Replace(Entete, ColBInit, ColB)

Ce n'est peut être pas la meilleure façon de procéder.
Voyons celle-ci :

Function Format_Entete(Entete As String) As String
Dim ColA As String, ColB As String, ColC As String, ColD As String

    Entete = Left(Entete, Len(Entete) - 4)

    ColA = Split(Entete, " |")(0)
'placer ici le traitement pour la colonne A

    'traitement colonne B
    ColB = Split(Entete, " |")(1)
    Do While Len(ColB) < 8
      ColB = "0" & ColB
    Loop

    'traitement colonne C
    'dans la colonne C, on veut d'abord ajouter deux 0 à la fin, dont acte :
    ColC = Split(Entete, " |")(2) & "00"
    Do While Len(ColC) < 12
        ColC = "0" & ColC
    Loop

  'traitement colonne D
    ColD = Split(Entete, " |")(3)
    Do While Len(ColD) < 14
      ColD = "0" & ColD
    Loop

    'On formate la chaine de caractères de "sortie"
    Format_Entete = ColA & " |" & ColB & " |" & ColC & " |" & ColD
End Function

Supprime ton fichier texte, enregistre ton classeur excel, ferme tout et relance la macro.

Donne moi un exemple concret d'entête avant/après

Ce que j'entendais pas là :
avant (sur Excel) j'ai :
col A : 1
Col B : 30
Col C : 500
Col D : 2014618102830

Je veux obtenir, dans mon fichier txt :
1 |00000030|000000050000|20140618102830

Sub Main_CreationFichierTxt()
Dim MesDonnees()
Dim Chemin As String, Ligne As String
Dim num As Integer
Dim i As Long, j As Long, DernLigne As Long
num = FreeFile
With Sheets("Feuil1") ' A ADAPTER le nom de la feuille contenant les données
  'A ADAPTER au cas ou la colonne A ne serait pas la plus "longue"
  DernLigne = .Range("D" & Rows.Count).End(xlUp).Row
  'A ADAPTER ici ne traite que les colonnes de A à E
  MesDonnees = .Range("A1:D" & DernLigne).Value
End With
'A ADAPTER : chemin d'accès complet pour le stockage du fichier txt
Chemin = "C:\Users\MOI-MEME\Desktop"
'A ADAPTER le nom du fichier txt à créer
Open Chemin & "\MonFichierTexte.txt" For Output As #num
'Boucle sur la liste des mots
For i = LBound(MesDonnees, 1) To UBound(MesDonnees, 1)
  For j = LBound(MesDonnees, 2) To UBound(MesDonnees, 2)
    If j = LBound(MesDonnees, 2) Then
      Ligne = MesDonnees(i, j) & " |"
    Else
      Ligne = Ligne & MesDonnees(i, j) & " |"
    End If
  Next j
  Ligne = Left(Ligne, Len(Ligne) - 2)
  'Ici on appelle la fonction de traitement d'entêtes...
  If i = LBound(MesDonnees, 1) Then Format_Entete Ligne
  'Ecrit dans le fichier texte ligne par ligne
  Print #1, Ligne
  Ligne = ""
Next i
'Fermeture
Close #num
End Sub
Function Format_Entete(Entete As String) As String
Dim ColA As String, ColB As String, ColC As String, ColD As String

    ColA = Split(Entete, " |")(0)
    Do While Len(ColA) < 3
      ColA = " " & ColA
    Loop

    'traitement colonne B
    ColB = Split(Entete, " |")(1)
    Do While Len(ColB) < 8
      ColB = "0" & ColB
    Loop

    'traitement colonne C
    'dans la colonne C, on veut d'abord ajouter deux 0 à la fin, dont acte :
    ColC = Split(Entete, " |")(2) & "00"
    Do While Len(ColC) < 12
      ColC = "0" & ColC
    Loop

  'traitement colonne D
    ColD = Split(Entete, " |")(3)
    Do While Len(ColD) < 14
      ColD = "0" & ColD
    Loop

    'On formate la chaine de caractères de "sortie"
    Format_Entete = ColA & " |" & ColB & " |" & ColC & " |" & ColD
End Function

De plus, j'ai l'impression que selon les fichiers traités ce ne doit pas être la même chose.....

Salut,

Je l'ai testé, il fonctionne exactement comme tu me l'avais demandé.
Colonne A : 3 caractères : exemple : deux espaces et un 1
Colonne B : 8 caractères : des zéros puis l'ancien champs de la colonne B
Colonne C : 12 caractères : des zéros puis l'ancien champs de la colonne C puis 2 zéros
Colonne D : 14 caractères.

Tu as tout pour réussir :
- le code,
- les explications,
- des liens de cours sur la manipulation des chaines de caractères.

Je ne peux donc rien faire de plus pour toi.

Pour moi ce sujet est clos.

Cordialement,
Pijaku