Rechercher valeur proche et afficher nom lign & col correspondan

Function rechMat(valeur As Double, matrice As Range, typeRetour As Long) As Variant  
    ' recherche dans 'matrice' le 1er nombre le plus proche supérieur ou égal à 'valeur'  
    ' 'matrice' contient les titres des lignes et colonnes  
    ' typRetour =1 : 1er nombre le plus proche supérieur ou égal à 'valeur'  
    ' typRetour =2 : nom de la ligne  
    ' typRetour =3 : nom de la colonne  
    '  
    Dim lig As Long, col As Long, delta As Double  
    Dim lig1 As Long, col1 As Long, delta1 As Double  
    Dim mat() As Variant  
    '  
    mat = matrice.Value  
    delta1 = 9 ^ 99  
    For lig = 2 To UBound(mat, 1)  
        For col = 2 To UBound(mat, 2)  
            delta = mat(lig, col) - valeur  
            If mat(lig, col) >= valeur And delta < delta1 Then  
                col1 = col: lig1 = lig  
                delta1 = delta  
            End If  
        Next col  
    Next lig  
    If lig1 = 0 Then  
        rechMat = CVErr(xlErrNA)  
    Else  
    Select Case typeRetour  
    Case 1  
        rechMat = mat(lig1, col1)  
    Case 2  
        rechMat = mat(lig1, 1)  
    Case 3  
        rechMat = mat(1, col1)  
    End Select  
    End If  
End Function