VBA Excel suppression des doublons

Sub Doublon()
 
    Dim Plage_E As Range
    Dim Plage_F As Range
    Dim PlageTempo As Range
    Dim Cel_E As Range
    Dim Cel_F As Range
    Dim I As Integer
    
    'défini les plages
    Set Plage_E = Range([E1], [E65536].End(xlUp))
    Set Plage_F = Range([F1], [F65536].End(xlUp))
 
    For Each Cel_E In Plage_E
    
        'recherche la valeur de chaque cellule de la colonne E dans
        'la colonne F
        Set Cel_F = Plage_F.Find(Cel_E, , xlValues)
        
        'si une occurence est trouvé dans la colonne F
        'inscrit "Doublon" dans la cellule concernée de la colonne E
        If Not Cel_F Is Nothing Then
        
                Cel_E = "Doublon"
 
        End If
        
    Next Cel_E
    
    'pour la suppression de cellules, il est préférable
    'de parcourir la plage en partant de la fin
    For I = Plage_E.Count To 1 Step -1
        
        'si la cellule Ex contient le mot "Doublon"
        'les cellules de Ax à Ex sont supprimées
        If Plage_E(I) = "Doublon" Then
        
            Range(Plage_E(I).Offset(0, -4), Plage_E(I)).Delete xlUp
            
        End If
    Next I
    
End Sub

Sub supp_doublons() 
Dim Lig_E As Long, Lig_F As Long 
Dim Dico_F As Object, Cptr As Long 
Dim Ref  'a compléter 
Dim T_out, Cptr_t As Long 
Dim start As Single 'pour essai rapidité 

start = Timer 'essai 
'mémorise colonne F 
Lig_F = Cells(Cells.Rows.Count, 6).End(xlUp).Row 
Set Dico_F = CreateObject("scripting.dictionary") 
For Cptr = 2 To Lig_F 
    Ref = Cells(Cptr, 6) 
    If Not Dico_F.exists(Ref) Then 
        Dico_F.Add Ref, Ref 
    End If 
Next 

'mémorise lignes en doublon dans E 
Lig_E = Cells(Cells.Rows.Count, 5).End(xlUp).Row 
ReDim T_out(0) 
For Cptr = 2 To Lig_E 
    ReDim Preserve T_out(Cptr_t) 
    Ref = Cells(Cptr, 5) 
    If Dico_F.exists(Ref) Then 
        T_out(Cptr_t) = Cells(Cptr, 5).Row 
       Cptr_t = Cptr_t + 1 
    End If 
Next 

'supprime les valeurs en doublons colonne A à E 
Application.ScreenUpdating = False 
For Cptr = 0 To UBound(T_out) - 1 
    Range(Cells(T_out(Cptr), 1), Cells(T_out(Cptr), 5)).Clear 
Next 

' supprime les cellules vides dans la colonne E et trie 
Range("E2:E" & Lig_E).Sort Range("E2") 

MsgBox Timer - start & " secondes" 

End Sub

Range("E2:E" & Lig_E).SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
au lieu de
Range("E2:E" & Lig_E).Sort Range("E2")