Macro excel-PJ en PDF

Fermé

Pdf
Macro

laclass91 Messages postés 2 Date d'inscription mardi 9 octobre 2018 Statut Membre Dernière intervention 14 octobre 2018 - 9 oct. 2018 à 11:52
cs_Le Pivert Messages postés 7903 Date d'inscription jeudi 13 septembre 2007 Statut Contributeur Dernière intervention 11 mars 2024 - 15 oct. 2018 à 14:14

Bonjour à tous,
j'aurai besoin de votre aide SVP pour finaliser mon petit programme,

Sub test()

Dim LaDate$, Nom$, Rep$ 'Déclaration des variables

LaDate = Format(Now, "yyyy_mm_dd_")
Nom = "…….." 'Nom de l'onglet à entregistrer
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Rep & Nom & "_" & LaDate & ".pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
From:=1, To:=1, OpenAfterPublish:=False '

End Sub

j'arrive a l'enregistrer mais pas a l'envoyer en pdf ...

j'ai un tableau excel lequel je renseigne chaque jour, mon but avec la macro c'est d’enregistrer une copie en pdf (avec la date du jour) de ce tableau et diffuser par email a plusieurs personnes

merci beaucoup

A voir également:

Macro excel pour les nuls pdf
Lire le coran en français pdf - Télécharger - Histoire & Religion
Liste déroulante excel - Guide
Tableau croisé dynamique pour les nuls pdf - Guide
Telecharger macro convertir chiffre en lettre excel - Télécharger - Tableur
Formule excel - Guide

4 réponses

Réponse 1 / 4

cs_Le Pivert Messages postés 7903 Date d'inscription jeudi 13 septembre 2007 Statut Contributeur Dernière intervention 11 mars 2024 728
9 oct. 2018 à 12:18

Bonjour,

comme ceci:

Dim LaDate$, Nom$, Rep$ 'Déclaration des variables 
LaDate = Format(Now, "yyyy_mm_dd_") 
Nom = "…….." 'Nom de l'onglet à entregistrer 
ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        Rep & Nom & "_" & LaDate & ".pdf", Quality:= _
        xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
      From:=1, To:=1, OpenAfterPublish:=False 
    Application.Dialogs(xlDialogSendMail).Show

laclass91
9 oct. 2018 à 23:34

bonsoir ,
merci de votre réponse rapide, malheureusement ça fonctionne pas une fois assembler, erreur d’exécution "5"
argument ou appel de procédure incorrect sur cette partie ""ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Rep & Nom & "_" & LaDate & ".pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
From:=1, To:=1, OpenAfterPublish:=False"""

Réponse 3 / 4

cs_Le Pivert Messages postés 7903 Date d'inscription jeudi 13 septembre 2007 Statut Contributeur Dernière intervention 11 mars 2024 728
Modifié le 10 oct. 2018 à 08:55

Fonctionne très bien comme ceci:

Sub test()
Dim LaDate$, Nom$, Rep$ 'Déclaration des variables
LaDate = Format(Now, "yyyy_mm_dd_") & Format(Time, "hh_mm_") 'formatage de la date et heure
Nom = "test" 'Nom de l'onglet à entregistrer
Rep = ThisWorkbook.Path & "\" ' Chemin du répertoire à adapter depuis votre PC
ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Rep & Nom & "_" & LaDate & ".pdf", Quality:= _
xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
From:=1, To:=1, OpenAfterPublish:=False
Application.Dialogs(xlDialogSendMail).Show
MsgBox "L'email a bien été transmis aux destinataires suivants: ***@***"
End Sub

là tu remplis ton mail manuellement pour les destinataires etc.

sinon il faut passer par cela:

https://excel-malin.com/codes-sources-vba/envoyer-un-email-avec-excel/

voir aussi ceci pour plusieurs destinataires:

https://www.developpez.net/forums/d528767/logiciels/microsoft-office/excel/macros-vba-excel/envoyer-email-plusieurs-destinataires-vba/#post3158361

Réponse 4 / 4

laclass91 Messages postés 2 Date d'inscription mardi 9 octobre 2018 Statut Membre Dernière intervention 14 octobre 2018
14 oct. 2018 à 21:48

bonsoir,
merci pour vos réponse et votre aide,
malheureusement quand j'exécute la macro j'ai toujours en PJ un fichier excel au lieu du fichier PDF

merci encore
Cdlt

cs_Le Pivert Messages postés 7903 Date d'inscription jeudi 13 septembre 2007 Statut Contributeur Dernière intervention 11 mars 2024 728
15 oct. 2018 à 08:30

voir ceci:

http://www.maitrise-excel.com/excel-outlook-envoi-mail-macro-excel-envoi-email-piece-jointe/

@+

cs_Le Pivert Messages postés 7903 Date d'inscription jeudi 13 septembre 2007 Statut Contributeur Dernière intervention 11 mars 2024 728
Modifié le 15 oct. 2018 à 14:17

Avec ce lien tu as tout pour le faire!

https://excel-malin.com/codes-sources-vba/envoyer-un-email-avec-excel/

comme ceci:

Option Explicit
Private Sub CommandButton1_Click()
TestEnvoiEmail_Variables
End Sub
Sub TestEnvoiEmail_Variables()
'par Excel-Malin.com ( https://excel-malin.com )

'définition des variables
Dim MonSujet As String
Dim MonDestinataire As String
Dim MonContenu As String
Dim MaPieceJointe As String
 Dim sFilename As String 'Nom du fichier
Dim sRep As String 'Répertoire de sauvegarde
Dim LaDate$, Nom$, Rep$ 'Déclaration des variables
LaDate = Format(Now, "yyyy_mm_dd_") & Format(Time, "hh_mm_") 'formatage de la date et heure
Nom = "test" 'Nom de l'onglet à entregistrer
sRep = ThisWorkbook.Path & "\" 'Répertoire de sauvegarde (si non spécifié, répertoire actif par défaut)
 sFilename = Nom & "_" & LaDate & ".pdf" 'Nom du fichier
 ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sRep & sFilename, _
 Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
 OpenAfterPublish:=False
'attribution des valeurs aux variables
MonSujet = "Test d'email d'Excel avec variables"
MonDestinataire = "paul@test.fr;marie@test.fr;contact@monentreprise.ca"
MonContenu = "Bonjour Jean, voici un petit message de test... Avec un fichier en plus."
MaPieceJointe = sRep & sFilename
    
    'test envoi de l'email
        Call EnvoyerEmail(MonSujet, MonDestinataire, MonContenu, MaPieceJointe)

MsgBox "Test terminé..."
End Sub
Sub EnvoyerEmail(ByVal Sujet As String, ByVal Destinataire As String, ByVal ContenuEmail As String, Optional ByVal PieceJointe As String)
'par Excel-Malin.com ( https://excel-malin.com )

On Error GoTo EnvoyerEmailErreur

'définition des variables
Dim oOutlook As Outlook.Application
Dim WasOutlookOpen As Boolean
Dim oMailItem As Outlook.MailItem
Dim Body As Variant

Body = ContenuEmail

    'vérification si le Contenu du mail n'est pas vide. Si oui, email n'est pas envoyé. Si vous voulez pouvoir envoyer les email vides, mettez en commentaire les 4 lignes de code qui suivent.
    If (Body = False) Then
        MsgBox "Mail non envoyé car vide", vbOKOnly, "Message"
        Exit Sub
       End If
    
    'préparer Outlook
    PreparerOutlook oOutlook
    Set oMailItem = oOutlook.CreateItem(0)
    
    'création de l'email
    With oMailItem
        .To = Destinataire
        .Subject = Sujet
        
        'CHOIX DU FORMAT
        '----------------------
        'email formaté comme texte
            .BodyFormat = olFormatRichText
            .Body = Body
            
            'OU
            
        'email formaté comme HTML
            '.BodyFormat = olFormatHTML
            '.HTMLBody = "<html><p>" & Body & "</p></html>"
        '----------------------
        
        If PieceJointe <> "" Then .Attachments.Add PieceJointe

       .Display   '<- affiche l'email (si vous ne voulez pas l'afficher, mettez cette ligne en commentaire)
       .Save      '<- sauvegarde l'email avant l'envoi (pour ne pas le sauvegarder, mettez cette ligne en commentaire)
       .Send      '<- envoie l'email (si vous voulez seulement préparer l'email et l'envoyer manuellement, mettez cette ligne en commentaire)
    End With
    
   'nettoyage...
    If (Not (oMailItem Is Nothing)) Then Set oMailItem = Nothing
    If (Not (oOutlook Is Nothing)) Then Set oOutlook = Nothing
    
   Exit Sub

EnvoyerEmailErreur:
    If (Not (oMailItem Is Nothing)) Then Set oMailItem = Nothing
    If (Not (oOutlook Is Nothing)) Then Set oOutlook = Nothing
  
    MsgBox "Le mail n'a pas pu être envoyé...", vbCritical, "Erreur"
End Sub

Private Sub PreparerOutlook(ByRef oOutlook As Object)
'par Excel-Malin.com ( https://excel-malin.com )

'------------------------------------------------------------------------------------------------
'Ce code vérifie si Outlook est prêt à envoyer des emails... Et s'il ne l'est pas, il le prépare.
'------------------------------------------------------------------------------------------------
On Error GoTo PreparerOutlookErreur


On Error Resume Next
    'vérification si Outlook est ouvert
    Set oOutlook = GetObject(, "Outlook.Application")
    
    If (Err.Number <> 0) Then 'si Outlook n'est pas ouvert, une instance est ouverte
        Err.Clear
        Set oOutlook = CreateObject("Outlook.Application")
    Else    'si Outlook est ouvert, l'instance existante est utilisée
        Set oOutlook = GetObject("Outlook.Application")
        oOutlook.Visible = True
    End If
    Exit Sub

PreparerOutlookErreur:
    MsgBox "Une erreur est survenue lors de l'exécution de PreparerOutlook()..."
End Sub

Ne pas oublier d'aller dans Outils- Référence

cocher la Référence Microsoft Outlook X.0 Object Library

voilà

@+

Discussions similaires

Envoi mail automatique avec fichier joint PDF

Macro : envoyer PDF en PJ Outlook

Faire une macro enregistrement automatique fichier word en pdf

Macro enregistrer PDF dans dossier spécifique

Enregistrer doc excel en pdf, avec nom variable + impression.

macro excel envoi Pièce jointe en pdf

Discussions similaires

Newsletters