Liste sans doublon récupérée dans un autre dossier excel

Sub Macro1()
Dim CD As Workbook 'déclare la variable CD (Classeur Destination)
Dim OD As Worksheet 'déclare la variable OD (Onglet Destination)
Dim CH As String 'déclare la variable CH (CHemin d'accès)
Dim CS As Workbook 'déclare la variable CS (Classeur Source)
Dim OS As Worksheet 'déclare la variable OD (Onglet Source)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim TC As Variant 'déclare la variable TC (Tableau de Cellules)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim I As Integer 'déclare la variable I (Incrément)
Dim TMP As Variant 'déclare la variable TMP (tableau TeMPoraire)

Set CD = ThisWorkbook 'définit le classeur destination CD
Set OD = CD.Sheets("Feuil1") 'définit l'onglet destination OD (à adapter à ton cas)
CH = "C:\Users\Anakin\Documents\VBA" 'chemin à adapter à ton cas évidemment...
'si il se trouve dans le même dossier que "book2.xlsm" tu peux utiliser :
'CH = CD.Path & "\"
On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
Set CS = Workbooks("book1.xlsm") 'définit le classeur source CS (génère une erreur si ce classeur n'est pas ouvert)
If Err <> 0 Then 'si une erreur a été générée
    Err = 0 'annule l'erreur
    Workbooks.Open (CH & "\book1.xlsm") 'ouvre le classeur
    Set CS = ActiveWorkbook 'définit le classeur source CS
End If 'fin de la condition
On Error GoTo 0 'annule la gestion des erreurs
Set OS = CS.Sheets("Feuil1") 'définit l'onglet source (à adapter à ton cas)
'définit la dernière ligne éditée DL de la colonne 1 (=A) de l'onget source OS (colonne à adapter à ton cas)
DL = OS.Cells(Application.Rows.Count, 1).End(xlUp).Row
TC = OS.Range("A1:A" & DL) 'définit le tableau de cellules TC (tu adapteras aussi la colonne à ton cas)
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For I = 1 To UBound(TC, 1) 'boucle sur toutes les lignes I du tableau de cellules TC en partant de la première (à adapter à ton cas)
    D(TC(I, 1)) = "" 'alimente le dictionnaire D
Next I 'prochaine ligne de la boucle
TMP = D.Keys 'récupère dans le tableau temporaire TMP la liste des éléments du dictionnaire D sans doublon
Call tri(TMP, LBound(TMP, 1), UBound(TMP, 1)) 'lance la procédure de tri alphabétique
For I = 0 To UBound(TMP) 'boucle sur tous les éléments du tableau temporaire TMP (sans doublon et trié)
    OD.Cells(I + 1, 1).Value = TMP(I) 'renvoie la valeur de TMP(I) dans la cellule ligne I+1 colonne 1 de l'onglet OD (à adapter à ton cas)
Next I 'prochaine élément de la boucle
CS.Close SaveChanges:=False 'ferme le classeur source CS sans enregister les changements
End Sub

Sub tri(a As Variant, gauc As Integer, droi As Integer) ' Quick sort tiré du site de Jacques BOISGONTIER : http://boisgontierjacques.free.fr/pages_site/Dictionnaire.htm
Dim ref As String
Dim g As Integer
Dim D As Integer

ref = a((gauc + droi) \ 2)
g = gauc: D = droi
Do
    Do While a(g) < ref: g = g + 1: Loop
    Do While ref < a(D): D = D - 1: Loop
    If g <= D Then
        temp = a(g): a(g) = a(D): a(D) = temp
        g = g + 1: D = D - 1
    End If
Loop While g <= D
If g < droi Then Call tri(a, g, droi)
If gauc < D Then Call tri(a, gauc, D)
End Sub