VBA Excel - Clic sur bouton page Internet Explorer [Résolu/Fermé]

Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
-
Bonjour,
Le code (détail ci-dessous) fonctionne très bien pour ouvrir le tableau PMU "Rapports probables"... Maintenant, je voudrais ensuite ouvrir le tableau "Simple Placé" (bouton à l'intérieur de "Rapports probables".
Je pensais y arriver en ré-utilisant ce code mais je coince.
Pouvez-vous m'aider ?
Jean-Luc

Sub essai01()
'
' essai01 Macro
'

'

Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim DivParent As HTMLSelectElement
Dim Enfants As HTMLSelectElement
Dim Petits_Enfants As HTMLSelectElement
Dim Flag As Boolean

IE.navigate "https://www.pmu.fr/turf/index.html#03012015/R1/C1"
IE.Visible = True
WaitIE IE
Set IEDoc = IE.document
Application.Wait Time + TimeSerial(0, 0, 2)
Set DivParent = IEDoc.getElementById("course-info-plus")
For Each Enfants In DivParent.Children
    For Each Petits_Enfants In Enfants.Children
        If Petits_Enfants.innerText = "Rapports probables" Then Petits_Enfants.Click: Flag = True: Exit For
    Next
    If Flag Then Exit For
Next
Set IE = Nothing
End Sub

Sub WaitIE(IE As InternetExplorer)
   Do Until IE.readyState = READYSTATE_COMPLETE
      DoEvents
   Loop
End Sub


EDIT: Ajout de la coloration syntaxique.
Afficher la suite 

7 réponses

Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
2190
0
Merci
Bonjour,

1- Lorsque tu places du code sur notre forum, merci d'utiliser les balises code à ta disposition.
Le mode d'emploi (au cas ou) est ICI.

2- Le titre est bien mieux comme cela. Non?

3- je vais regarder, analyser la page Internet Explorer et revenir te dire si possible ou non.
En attendant, je te recommande néanmoins la lecture de ce tutoriel : http://qwazerty.developpez.com/tutoriels/vba/ie-et-vba-excel/

@+

🎼 Cordialement,
Franck 🎶
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
2190
0
Merci
je vais regarder, analyser la page Internet Explorer et revenir te dire si possible ou non.

ça a été plus rapide que prévu car très simple cette fois...

Que nous apprends l'analyse du code source de la page, et, plus précisément de l'élément concerné?
Tout simplement qu'il s'agit d'un lien (balise <a></a>) écrit avec cette syntaxe :
<a class="btn" data-type-pari="SIMPLE_PLACE" href="#">Simple Placé</a>


Il nous faut donc, pour pouvoir cliquer sur ce lien :
1- Pointer le membre Document (cf tuto précédemment cité) => obligatoire car on vient de changer la page IE suite au clic généré par le code précédent)
2- boucler sur toutes les balises de cette page
3- stocker dans une collection les balises <a>
4- boucler sur cette collection de balises
5- si le texte du lien est : Simple placé, alors on clique et on sort de la boucle.

Ce qui s'écrit, en VBA :

Set IEDoc = IE.document
Set Coll_Liens = IEDoc.getElementsByTagName("a")
For Each Lien In Coll_Liens
    If Lien.innerText = "Simple Placé" Then Lien.Click: Exit For
Next


Code à ajouter en fin de macro précédente, comme ceci :
Option Explicit
'sources :
'http://qwazerty.developpez.com/tutoriels/vba/ie-et-vba-excel/

Sub DadaCourse()
Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim DivParent As HTMLSelectElement
Dim Enfants As HTMLSelectElement
Dim Petits_Enfants As HTMLSelectElement
Dim Flag As Boolean
Dim Coll_Liens As IHTMLElementCollection
Dim Lien As HTMLGenericElement

IE.navigate "https://www.pmu.fr/turf/index.html#03012015/R1/C1"
IE.Visible = True
WaitIE IE
Set IEDoc = IE.document
Application.Wait Time + TimeSerial(0, 0, 2)
Set DivParent = IEDoc.getElementById("course-info-plus")
For Each Enfants In DivParent.Children
    For Each Petits_Enfants In Enfants.Children
        If Petits_Enfants.innerText = "Rapports probables" Then Petits_Enfants.Click: Flag = True: Exit For
    Next
    If Flag Then Exit For
Next
Set IEDoc = IE.document
Set Coll_Liens = IEDoc.getElementsByTagName("a")
For Each Lien In Coll_Liens
    If Lien.innerText = "Simple Placé" Then Lien.Click: Exit For
Next
Set IE = Nothing
End Sub

Sub WaitIE(IE As InternetExplorer)
   Do Until IE.readyState = READYSTATE_COMPLETE
      DoEvents
   Loop
End Sub


NOTA (très important) : Lorsque je place un lien vers une source, dans le code, sous la forme d'un commentaire, il convient de le laisser chez toi dans la macro de manière identique. Cela permet de reconnaitre le bon travail d'un bénévole sur Internet...
bonjour,

comment puis je copier cela sur excel?

eric
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3
0
Merci
ok, je m'y emploie !!
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3
0
Merci
Salut Franck,
Absent quelques jours, je m'en occupe dés mon retour et je te tiendrais informé.
Encore un grand grand merci !!
Bonne journée
Jean-Luc
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3
0
Merci
Bonjour Franck,

3 mots à te dire: SUPER,... GRAND MERCI !!!

Ca fonctionne très bien (et je tiens compte de ton Nota)

Vive le très bon travail d'un très bon et disponible bénévole.
Plein de bonnes choses pour toi.

Jean-Luc
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3
0
Merci
Bonjour Franck,
Tous les jours je récupère des informations du site du PMU grâce au "code" que tu m'as fourni en tout début janvier... et cela fonctionne merveilleusement bien (je t'en remercie encore).

Aujourd'hui, je voudrais une information de plus sur ce site: "Tous les rapports". Après plusieurs heures de tâtonnement, je n'ai toujours pas trouvé le bon "code", aussi je m'en remets encore une fois à toi.
Une fois le site du PMU ouvert sur la bonne course, je voudrais simplement ouvrir à l'écran le tableau "Tous les rapports" (à l'écran, bouton du côté gauche sous ou à la suite des boutons colorés des différents paris).

Par avance un grand merci !!

Ci-après, le code utilisé (et fourni par toi) pour ouvrir la page initiale du PMU.
En A1, l'URL de la course, par exemple :
https://www.pmu.fr/turf/index.html#24022015/R1/C2

Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim DivParent As HTMLSelectElement
Dim Enfants As HTMLSelectElement
Dim Petits_Enfants As HTMLSelectElement
Dim Flag As Boolean
Dim Coll_Liens As IHTMLElementCollection
Dim Lien As HTMLGenericElement

IE.navigate "" & [A1].Value
IE.Visible = True
Application.Wait Time + TimeSerial(0, 0, 2)
Set IEDoc = IE.document
Application.Wait Time + TimeSerial(0, 0, 1)


(Je ne suis pas sûr de ma manipulation pour les CS, toutes mes excuses si c'est faux)
dadacourse
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3 > pijaku
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
-
J'ai recommencé et "rien à faire", la course s'ouvre bien mais pas le tableau "Tous les rapports"
pijaku
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
2190 > dadacourse
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
-
J'ai recommencé, tout fonctionne...
Essaye ceci, ta connexion Internet est peut être plus lente que la mienne :
Sub TousLesRapports()
Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim coll_Li As IHTMLElementCollection
Dim Li As HTMLGenericElement

'ouverture de la page Internet Explorer
IE.navigate "https://www.pmu.fr/turf/index.html#24022015/R1/C2"
IE.Visible = True
'attente du chargement complet de la page IE
WaitIE IE
Application.Wait Time + TimeSerial(0, 0, 2)
'on cible le document de cette page
Set IEDoc = IE.document
'attente du chargement complet de l'élément Document de la page IE
WaitDoc IEDoc
Application.Wait Time + TimeSerial(0, 0, 2)
'on créé notre collection contenant toutes les balises <li>
Set coll_Li = IEDoc.getElementsByTagName("li")
'on boucle sur toutes les balises <li> de notre collection
For Each Li In coll_Li
    'Si la className de la balise <li> est "actionbar-item js-all-report-button"
    If Li.className = "actionbar-item js-all-report-button" Then
        'on clique
        Li.Click
        'on quitte
        Exit For
    End If
Next
End Sub

Sub WaitIE(IE As InternetExplorer)
'attente du chargement complet de la page IE
   Do Until IE.readyState = READYSTATE_COMPLETE
      DoEvents
   Loop
End Sub

Sub WaitDoc(doc As HTMLDocument)
'attente du chargement complet de l'élément Document
  Do While Not doc.readyState = "complete"
    DoEvents
  Loop
End Sub
dadacourse
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3 > pijaku
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
-
Youpiii et bravo Franck
C'est exactement ça... le tableau des Rapports s'ouvre très bien.
Merci pour tout... ta disponibilité, ta compétence, ton travail et plein de choses encore.
Je te souhaite une très bonne journée !!
pijaku
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
2190 > dadacourse
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
-
Merci beaucoup.
La bonne journée à toi également.
A++
pijaku
Messages postés
12253
Date d'inscription
jeudi 15 mai 2008
Statut
Modérateur
Dernière intervention
19 juillet 2019
2190 > dadacourse
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
-
Au fait, si tu gagnes le gros lot, penses à moi lol ;-)
A++
Messages postés
96
Date d'inscription
lundi 12 décembre 2011
Statut
Membre
Dernière intervention
5 juin 2019
3
0
Merci
Bonsoir Franck
Je viens tout juste de découvrir ta réponse. Dés demain matin je m'y attelle et te tiens au courant.
Grand merci et bonne soirée !!