Comment mettre en place un compteur en fonction de la date

Option Explicit
'-------
Sub compter_lesvides()
Dim Derlig As Long, T_in, Idx As Long, Jour As Long
Dim D_date As Object
Dim test
'----initialisations
    Application.ScreenUpdating = False
    With Sheets("test")
        Derlig = .Columns("C").Find("*", , , , , xlPrevious).Row
        'stocke en RAM le tableau
        T_in = .Range("C6:D" & Derlig)
        Set D_date = CreateObject("scripting.dictionary")
'-----collecte et traitement
        For Idx = 1 To UBound(T_in)
            Jour = CLng(T_in(Idx, 1))
            If Not D_date.Exists(Jour) Then
                D_date.Add Jour, 0
                If T_in(Idx, 2) = "" Then D_date.Item(Jour) = 1
            Else
                If T_in(Idx, 2) = "" Then D_date.Item(Jour) = D_date.Item(Jour) + 1
                'test = D_date.Item(Jour)
            End If
        Next
    'restitution
        .Range("G7:H10000").Clear
        With .Range("G7").Resize(D_date.Count, 1)
            .Value = Application.Transpose(D_date.keys)
            .NumberFormat = "dd/mm/yyyy"
        End With
        .Range("H7").Resize(D_date.Count, 1) = Application.Transpose(D_date.items)
        .Range("G7:H" & D_date.Count + 7).Borders.Weight = xlThin
       End With
End Sub