[Excel VBA]=LIEN_HYPERTEXTE dans un tableau dynamique

Sub Essai()
Dim MonLien As String
Dim MesScreens(0) As String

MonLien = "http://www.commentcamarche.net/forum/affich-29277237-excel-vba-lien-hypertexte-dans-un-tableau-dynamique"
MesScreens(0) = "=HYPERLINK(""" & MonLien & """,""Screenshot"")"
Cells(1, 1).Formula = MesScreens(0)
End Sub

Do While ID_test <> "FIN"                                                                                                           'Boucle "TANT QUE" la ligne ne contient pas "FIN". "FIN" est nécessaire car les cellules fusionnées n'ont pour valeur que celle de la cellule la plus en haut à gauche
    If ID_test <> "" Then                                                                                                           'Permet d'éviter les doublons dans les cellules fusionnées
        Do While Device <> ""                                                                                                       'Boucle "TANT QUE" la colonne n'est pas vide
            If Resultat = "OK BUT" Or Resultat = "NOK" Then                                                                         'Récupération des résultats qui présentent un problème
                Probleme = True                                                                                                     'Booléen de contrôle pour l'écriture dans le tableau
                
                Set myRegExp = New RegExp                                                                                           'Création du Ragexp
                myRegExp.IgnoreCase = True                                                                                          'L'expression régulière ignore la casse
                myRegExp.Global = True                                                                                              'Définit la recherche sur toutes les occurences et pas seulement sur la première (Les occurences sont séparées par le retour à la ligne)
                myRegExp.Pattern = "(> )|(.*)"                                                                                      '(> ) recherche toutes les lignes commençant comme "> " pour les isoler (et les ignorer par la suite)
                                                                                                                                    ' | correspond au séparateur "OU". Il sépare les commentaires commençant par "> " des commentaires uniques qui n'en possèdent pas
                                                                                                                                    '(.*) recherche tout ce qu'il y a après la première occurence
                                                                                                                                    
                Set myMatches = myRegExp.Execute(Sheets("tests").Cells(ligne_ID_test, col_Resultat + 1).Value)                      'Execute le ragexp sur la cellule "Commentaire" ciblée
                For Each myMatch In myMatches                                                                                       'Boucle "TANT QUE" par occurence trouvée dans les commentaires
                    For i = 0 To myMatch.SubMatches.Count - 1                                                                       'fonction "POUR" par sous-occurence de l'occurence (par ligne donc, la première sous-occurence étant (> ), la deuxième (.*) ). On enlève 1 car on veut boucler sur les sous-occurences en commençant la boucle à 0. Comme nous commençons à 0 et qu'il nous faut 2 "tours" de boucle, et que SubMatches.Count = 1, il faut lui enlever 1
                        If myMatch.SubMatches(i) <> "> " And myMatch.SubMatches(i) <> "" Then                                       'Fonction "SI" qui ignore la première sous-occurence (> )
                            If InStr(1, myMatch.SubMatches(i), "http") <> 0 Then                                                    'Vérifie si le commentaire contient un lien http. Dans ce cas, il l'extraira dans un deuxième Ragexp et le lien récupéré remplacera le screenshot d'origine. Sinon, il récupèrera les infos du bug avec le screen fourni
                                
                                Set myRegExp2 = New RegExp                                                                          'Création d'une deuxième expression régulière Ragexp
                                myRegExp2.IgnoreCase = True                                                                         'L'expression régulière ignore la casse
                                myRegExp2.Global = True                                                                             'Définit la recherche sur toutes les occurences et pas seulement sur la première (Les occurences sont séparées par le retour à la ligne)
                                myRegExp2.Pattern = "(.*)\((.*)\)"                                                                  'La première sous-occurence contient l'intégralité du texte placé avant la deuxième sous-occurence
                                                                                                                                    'La deuxième sous-occurence contient tout ce qui est contenu entre parenthèses (ou entre les dernières parenthèses de la ligne) tout en excluant celles-ci
                                Set myMatches2 = myRegExp2.Execute(myMatch.SubMatches(i))                                           'Création de la deuxième expression régulière, imbriquée dans le résultat de la première contenant le lien http
                                
                                For Each myMatch2 In myMatches2                                                                     'Boucle "TANT QUE" par occurence trouvée dans le commentaire (il n'y a qu'une seule occurence ici (le commentaire contenant le http), mais c'est nécessaire pour travailler sur les sous-occurences
                                    ReDim Preserve mesComments(Indtab)                                                              'Redimentionnement du tableau contenant tous les bugs individuellement
                                    ReDim Preserve mesScreens(Indtab)                                                               'Redimentionnement du tableau contenant tous les screenshots liés à leur bug
                                    mesComments(Indtab) = myMatch2.SubMatches(0)                                                    'Récupération du bug individuel
                                    mesScreens(Indtab) = "=LIEN_HYPERTEXTE(""" & myMatch2.SubMatches(1) & """;""Screenshot"")"      'Récupération du screenshot associé pré-formaté. Pour inscrire un guillemet dans une variable en VBA, on la double
                                Next
                            
                            Else                                                                                                    'Si le commentaire n'a pas de lien HTTP, on récupère le bug et toutes ses infos dans leurs tableau respectifs
                                ReDim Preserve mesComments(Indtab)                                                                  'Redimentionnement du tableau contenant tous les bugs individuellement
                                ReDim Preserve mesScreens(Indtab)                                                                   'Redimentionnement du tableau contenant tous les screenshots liés à leur bug
                                mesComments(Indtab) = myMatch.SubMatches(i)                                                         'Récupération du bug individuel
                                mesScreens(Indtab) = Sheets("Tests").Cells(ligne_ID_test + 1, col_Resultat + 1).FormulaLocal        'Récupération du Screenshot présent en dessous du commentaire sur le plan de test. Le suffixe FormulaLocal permet de récupérer la formule et non juste "Screenshot".
                            End If
                            ReDim Preserve mesID_Test(Indtab)                                                                       'Redimentionnement du tableau contenant les ID de test (3.1.1, 3.2.2 etc.)
                            ReDim Preserve mesResultats(Indtab)                                                                     'Redimentionnement du tableau contenant les résultats des commentaires (OK, OK BUT etc.)
                            ReDim Preserve mesDevices(Indtab)                                                                       'Redimentionnement du tableau contenant tous les devices associés à leur bug
                            ReDim Preserve mesVersionsOS(Indtab)                                                                    'Redimentionnement du tableau contenant tous les
                            mesID_Test(Indtab) = ID_test                                                                            'Récupération de l'ID du test correspondant au bug
                            mesResultats(Indtab) = Resultat                                                                         'Récupération du résultat correspondant au bug
                            mesDevices(Indtab) = Device                                                                             'Récupération du device lié au bug
                            mesVersionsOS(Indtab) = VersionOS                                                                       'Récupération de la version de l'OS
                            Indtab = Indtab + 1                                                                                     'Incrémentation de la ligne du tableau
                        End If
                    Next i
                Next myMatch
            End If
            If Sheets("Tests").Cells(ligne_Device, col_Device + 2).Value <> "" Then                                                 'Si la colonne n'est pas vide, on passe à la colonne suivante
            col_Device = col_Device + 2                                                                                             'Passage de la colonne du mobile au suivant
            col_Resultat = col_Resultat + 2                                                                                         'Passage de la colonne de Test à Retest, ou inversement
            Else
            col_Device = col_Device + 4                                                                                             'Sinon, on passe directement au mobile suivant
            col_Resultat = col_Resultat + 4
            End If
            Device = Sheets("Tests").Cells(ligne_Device, col_Device)                                                                'Récupération du nouveau mobile
            VersionOS = Sheets("Tests").Cells(ligne_VersionOS, col_Device)                                                          'Récupération de la version de l'OS du nouveau mobile
            Resultat = Sheets("Tests").Cells(ligne_ID_test, col_Resultat)                                                           'Récupération du résultat (OK, OK BUT, NOK etc.)
        Loop
    End If
    ligne_ID_test = ligne_ID_test + 1                                                                                               'Passage au cas de test suivant
    ID_test = Sheets("Tests").Cells(ligne_ID_test, col_ID_test)                                                                     'Récupération de l'ID du test
    col_Device = col_1er_Device                                                                                                                  'On repasse à la colonne du tout premier Device
    col_Resultat = col_1er_Resultat                                                                                                                'On repasse à la colonne du tout premier Résultat
    Device = Sheets("Tests").Cells(ligne_Device, col_Device)                                                                        'Récupération du mobile
    VersionOS = Sheets("Tests").Cells(ligne_VersionOS, col_Device)                                                                  'Récupération de la version de l'OS du mobile
    Resultat = Sheets("Tests").Cells(ligne_ID_test, col_Resultat)                                                                   'Récupération du résultat (OK, OK BUT, NOK etc.)
Loop