Comparer taille de fichiers dans 2 dossiers

Gui, add, text,    w50 y15 r1 section    ,In Folder1 
Gui, add, text,    w50 r1              ,In Folder2 
Gui, add, text,    w50 r1              ,Out Folder 
Gui, add, Edit,    w600 r1 vIN1Folder ys-5,D:\(chemin1)
Gui, add, Edit,    w600 r1 vIN2Folder,D:\chemin2 
Gui, add, Edit,    w600 r1 vOUTFolder,D:\chemindestination
Gui, add, Button,    w50 ys-8 gBut vIN1   , ... 
Gui, add, Button,    w50    gBut vIN2   , ... 
Gui, add, Button,    w50    gBut vOUT   , ... 
Gui, Add, ListView, x10 w660 r10, Filename|FileSize Dir1|FileSize Dir2|CandidateFolder 
Gui, add, Button,    w50 x680 h70 yp   gGo      , GO 
Gui, add, Button,    w50 x680 h30 yp+80 gExit , Exit 
Gui,show 
return 
    
But: 
   FileSelectFolder, fold 
   if (fold = "") 
      return 
   GuiControl,,%A_GuiControl%folder, %fold% 
return 

Go: 
   Gui, Submit, NoHide 
   if ( IN1Folder = "" || IN2Folder = "" || OUTFolder = "" ) { 
      msgbox, % "Missing files" 
      return 
   } 
   LV_Delete() 
   loop, %IN1Folder%\*.*   {       
      thisFile := A_LoopFileName 
      thisSize := A_LoopFileSize 
      IfExist, %IN2Folder%\%thisFile% 
      { 
         FileGetSize, size, %IN2Folder%\%thisFile% 
         smallerFileDir := thisSize < size ? "In1Folder" : thisSize > size ? "In2Folder" : "" 
         if (smallerFileDir <> "" ) { 
             
            LV_Add("", thisFile, thisSize, size, smallerFileDir)  
            FileCopy,% %smallerFileDir% "\" thisFile, %OUTFolder% 
         } 
      } 
   } 
   LV_ModifyCol() 
   LV_ModifyCol(2,"100 Integer") 
   LV_ModifyCol(3,"100 Integer") 
   LV_ModifyCol(4,"200") 
       
return 
exit: 
GuiEscape: 
GuiClose: 
   ExitApp 
return