Bonjour,

VB ou VBA ?

Exemple type sous VBA :

Option Explicit
'

Private Const BIF_RETURNONLYFSDIRS = 1
Private Const BIF_DONTGOBELOWDOMAIN = 2

Private Declare Function SHBrowseForFolder Lib "shell32" _
                        (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" _
                        (ByVal pidList As Long, _
                         ByVal lpBuffer As String) As Long
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" _
                        (ByVal lpString1 As String, _
                         ByVal lpString2 As String) As Long

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
     ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
'

Sub LocaliseFichier()

    Dim strFichier As String
    
    strFichier = Application.GetOpenFilename("Excel Files (*.xls), *.xls")
    
    MsgBox strFichier

End Sub
'

Sub LocaliseRepertoire()

    Dim strDossier As String
    
    strDossier = SelectFolder("Sélectionner le répertoire de destination :", 0)
    
    MsgBox strDossier
    
End Sub
'

Private Function SelectFolder(Titre As String, Handle As Long) As String

    Dim lpIDList As Long, strBuffer As String
    Dim strTitre As String, tBrowseInfo As BrowseInfo
    
    strTitre = Titre
    With tBrowseInfo
        .hWndOwner = Handle
        .lpszTitle = lstrcat(strTitre, "")
        .ulFlags = BIF_RETURNONLYFSDIRS + BIF_DONTGOBELOWDOMAIN
    End With
    
    lpIDList = SHBrowseForFolder(tBrowseInfo)
    
    If (lpIDList) Then
        strBuffer = String(260, vbNullChar)
        SHGetPathFromIDList lpIDList, strBuffer
        SelectFolder = Left(strBuffer, InStr(strBuffer, vbNullChar) - 1)
    End If

End Function
'