Problème de recherche Excel

Bonsoir cdh0904,
Avec une petite adaptation s’est possible :
Colonne A concaténer B et C
11 1 1 Cedric
12 1 2 Delphine
23 2 3 Maxime
24 2 4 Thomas
25 2 5 Romane
36 3 6 Charline
47 4 7 Xavier
48 4 8 Léon

Sur la feuille 2 en "A1" = 2 et en "B1" = 4
Dans "C1" =RECHERCHEV(A1&B1;Feuil1!A1:D8;4)
Résultat : Maxime
Salutations.
Jean-Pierre

Bonjour cdh0904,

La formule Recherche peut-être utilisée si 1 nombre correspond à 1 nom

matrice :
1 cedric
2 delphine
3 maxime
4 thomas
5 romane
6 charline
7 xavier
8 leon

Formule sur Feuil2 dans case B1 "=RECHERCHE(A1;Feuil1!A1:B8)" avec la valeur remplie en A1.

Je cherche pour ta matrice plus complexe... à 3 colonnes Alice.Catseyes
Nul n'est censé ignorer la loi

Salut,

si desous la même fonction, la deuxième incorpore une conditionnelle afin de ne pas afficher un 0 ou un messassage d'erreur si dans la cellule de selection aucune donnée n'y figure.

=RECHERCHEV($A$2;Feuil1!$A$1:$I$8;2)

=SI($A$2="";"";RECHERCHEV($A$2;Feuil1!$A$1:$I$8;2))

Explication de la formule rechercheV =si($A$2="";"";rechercheV($A$2;Eléve!$A$1:$I$8;2)) " =si($A$2="";""; est une conditionnelle afin qu'il n'y ait pas de résultat dans les cellules notes si aucun n° a été saisie pour la recherche, à mettre ou non. rechercheV est la fonction ($A$2; est la cellule de référence dans laquelle il sera saisie le numéro à rechercher, Feuil1! est le nom de l'onglet de feuille dans lequel la recherche sera faite $A$1:$I$8;est la plage de cellule dans laquelle la recherche doit être faîte et sera plus importante sur ton tableau 2)) est le n° de la colonne dans laquelle sera rechercher l'information et sera donc la cellule au point de jonction du n° sélectionné et de cette colonne.

A+

bonjour

C'est effectivement assez compliqué de trouver ta valeur de colonne C en fonction des valeurs A et B.

Si ton tableau est trié comme sur l'exemple, tu peux le faire avec cette formule

=INDIRECT("Feuil1!C"&EQUIV(Feuil2!A1;Feuil1!A1:A20;0)+EQUIV(Feuil2!B1;DECALER(Feuil1!A1;EQUIV(Feuil2!A1;Feuil1!A1:A20;0);1;20;1);0))

tes critères de recherche sont en Feuil2!A1 et Feuil2!B1
ton tableau est en Feuil1!A1:C20
il faut remplacer les 20 par le nombre de lignes de ton tableau

La formule fait l'affichage de la cellule concernée de la colonne C :
=INDIRECT("Feuil1!C"&
que l'on complète par la ligne avec la première position de la colonne A :
EQUIV(Feuil2!A1;Feuil1!A1:A20;0)
+
la première position de la colonne B :

EQUIV(Feuil2!B1;DECALER(Feuil1!A1;

trouvée dans le tableau déterminé par la colonne A décalé d'une colonne :

EQUIV(Feuil2!A1;Feuil1!A1:A20;0);1;20;1);0))
Toujours zen

Bonjour Le Pingou et à tous !

Le plus simple est la solution de LePingou
comme il est difficile de rechercher avec deux colonnes
il faut concaténer pour n'en avoir plus qu'une !
et il faut le faire sur les 2 feuilles , suffit d'avoir insérer une colonne et de frapper la formule
Dans la feuille où on va rechercher l'information il faut que le code recherché soit à gauche de la donnée que l'on veut ramener car on fonctionne par déplacement

Voir le fichier ici :
http://cjoint.com/?dso4seZ1a3 xkristi
Je ne détiens point la vérité , je te la laisse  volontiers ­...

=INDIRECT("Feuil1!C"&EQUIV(Feuil2!A1;Feuil1!A1:A20;0)-1+EQUIV(Feuil2!B1;DECALER(Feuil1!A1;EQUIV(Feuil2!A1;Feuil1!A1:A20;0)-1;1;20;1);0))

OK super

quand tu jugeras ton problème terminé n'oublies pas de le porter résolu

Merci

Bonjour Vaucluse,
Merci pour votre information et suggestion :
=SOMMEPROD((Feuil1!A1:A100=C1)*1;(Feuil1!B1:B100=B1)*1;Feuil­1!C1:C100)
Tel quel, le résultat de sommeproduit est toujours "0" et en modifiant le "C1" de Feuil1!A1:A100=C1 par "A1"
soit =SOMMEPROD((Feuil1!A1:A100=A1)*1;(Feuil1!B1:B100=B1)*1;Feuil1!C1:C100)
Le résultat est toujours zéro .... est oui la matrice "Feuil1!C1:C100" fait référence à du texte d'où sommeprod =0
Eh bien là je n'ai encore pas sortie la valeur de la colonne "C" correspondante :"Cedric,Delphine......Léon"

Salutations.
Jean-Pierre

Bonjour Vaucluse,
Ne soyez pas désolé, c'est une super idée, j'y ai réflèchi et voila se que l'on obtient :
=INDIRECT("Feuil1!C"&SOMMEPROD((Feuil1!A1:A8=A1)*1;(Feuil1!B1:B8=B1)*1;{1;2;3;4;5;6;7;8}))
Ce qui fonctionne à merveille selon les bases du poste du demandeur.
Il est aussi possible de remplacer {1;2;3;4;5;6;7;8} par la plage d'une colonne que l'on aura créer avec l'incrémentation de 1 à x selon le nombre de ligne désiré (nb identique au matrice de la "Sommeprod" dans notre cas : "X1:X8" = 1;2;3;4;5;6;7;8.
A une prochaine.

Salutations.
Jean-Pierre

Merci et bonne fête de Pâques.
Salutations.
Jean-Pierre