Aide fonction sed sous linux

sed -n '/Inscrits/,/résultat/{\§tdcd">[ ][ ]*[0-9][0-9]*§{N;s/<[^>]*>//g;s/\x20//g;P}}'

JP : Zen, my Nuggets ! ;-)
Le savoir n'est bon que s'il est partagé.

$ sed -n '/Inscrits/,/résultat/{\#tdcd">[ ][ ]*[0-9][0-9]*#{N;s/<[^>]*>//g;s/\x20//g;P}}' cmnoBpJozR_22001.html
408
36
372
10
362
185
177
408
43
365
2
363
7
1
2
53
6
2
13
110
9
28
5
127

JP : Zen, my Nuggets ! ;-)
Le savoir n'est bon que s'il est partagé.

-n
Affichage que sur demande

/Inscrits/,/résultat/
Adressage des lignes où sera confiner le traitement

{
Regroupement des commandes qui seront appliquées à la plage d'adresse

\#tdcd">[ ][ ]*[0-9][0-9]*#
Nouvel adressage à l'intérieur du précédent visant un motif particulier

        \#
        On définit un nouveau délimiteur (#) autre que celui par défaut (/)
        vu qu'il est contenu dans la chaîne recherchée.
        Donc on le protège (\) pour le définir.

        tdcd">[ ][ ]*[0-9][0-9]*
        L'expression régulière qui définit le motif recherché, à savoir :
        - qui commence par tdcd">
        - suivit éventuellement par au moins 1 espace ou plus [ ][ ]*
        - suivit éventuellement par au moins 1 chiffre ou plus [0-9][0-9]*

{
Regroupement des commandes qui seront appliquées à la nouvelle plage d'adresse

N;
Quant une ligne satisfaisant le motif est trouvée, on ajoute la ligne suivante dans l'espace de travail


s/<[^>]*>//g;
On efface tout ce qui se trouve entre "<" et ">" (on prend soin de spécifier de s'arrêter au 1er ">" trouvé ([^>]*), sans quoi tout ce qu'il y a entre le 1er "<" rencontrée et le dernier ">" sur la ligne serait effacer du fait de la gourmandise des expressions régulières), d'où la présence du flag "g" pour signifier la globalité de chaque expression


s/\x20//g;
On efface tous les espaces vides. On n'est pas obligé dans ce cas d'employer la valeur ASCII (\x20), on aurait très bien pu l'écrire : s/[ ][ ]*//g

P
On n'affiche que la 1ère partie (délimitée par le caractère fin de ligne "\n") du contenu de l'espace de travail, vu que tu ne veux pas les pourcentages, c'est d'ailleurs le pourquoi de l'emploi de la commande "N".

}
Fin du 2ème groupement de commandes

}
Fin 1er groupement de commandes

JP : Zen, my Nuggets ! ;-)
Le savoir n'est bon que s'il est partagé.

 sed -nse '/RAPPEL/,$ {/M\.\|Mme/{N;s#<[^>]*>##g;s/[ ]\{2,\}//g;s/\n/ : /p}}' 5356.html

JP : Zen, my Nuggets ! ;-)
Le savoir n'est bon que s'il est partagé.

[tmpfs]$ cat script.sed
#n
/ELECTIONS/,/officiels/ {
    // d
    /strong/ {
        N
        s/<.*>//
        p
    }
}
/RAPPEL/,$ {
    /M\.\|Mme/ {
        n
        N
        s#<[^>]*>##g
        s/[ ]\{2,\}//g
        s/\n/ : /p
    }
}

[tmpfs]$ sed -f script.sed -s *.html

          HAUTE GARONNE
        (31) -- 1ère circonscription
Extrême gauche : 2 115
Front national : 1 304
Socialiste : 12 758
Divers : 0
Divers : 401
Extrême gauche : 1 275
UDF-Mouvement Démocrate : 3 869
Les Verts : 2 199
Divers : 27
Extrême gauche : 219
Chasse Pêche Nature Traditions : 120
Divers gauche : 203
Divers : 5
Divers droite : 302
Divers : 102
Divers : 108
Ecologiste : 306
Majorité présidentielle : 15 152
          HAUTE GARONNE
        (31) -- 2ème circonscription
Union pour un Mouvement Populaire : 25 587
Front national : 2 336
Divers : 0
Mouvement pour la France : 598
Les Verts : 2 793
Divers : 552
Divers : 6
Socialiste : 24 733
Extrême gauche : 1 977
Communiste : 1 941
Extrême gauche : 309
Chasse Pêche Nature Traditions : 576
Majorité présidentielle : 2 795
UDF-Mouvement Démocrate : 5 982
Divers droite : 83
[tmpfs]$

JP : Zen, my Nuggets ! ;-)
Le savoir n'est bon que s'il est partagé.