[SED] substitution [Résolu]

Salut,

La 1ère expression enlève les commentaires sur une ligne, la 2nd sur plusieurs lignes :

sed -e 's!/\*.*\*/!!' -e '/\/\*/,/\*\//d'

;-))

une fois de plus, merci jicipy !

la 1° expression, je l'avais, par contre la 2° marche bien sauf ds le cas suivant :
toto=0; /* commentaire
sur plusieurs lignes */

c'est pour ca que je pensais faire la methode ci dessus en supprimant les sauts de lignes, pour avoir tous les commentaires sur une ligne...

une autre idée ?

$ cat plop
toto=0;

/* ======================
blabla
blabla
blabla
=======================*/

toto=0; /* commentaire
blabla
blabla
blabla
sur plusieurs lignes */

toto=1;
/* comment */
toto=2;

$ sed -e 's!/\*.*\*/!!' -e '/;[ ]*\/\*/{:z; N; s!/\*.*\*/!!;Tz}' -e'/\/\*/,/\*\//d' plop
toto=0;


toto=0;

toto=1;

toto=2;

;-))

Merci encore !

J'admet qu'on approche de la perfection, mais j'ai encore trouvé un cas où ca ne marche pas... :
#define ONE 1 /* ceci est un commentaire sur
plusieurs lignes */

C'est vrai je suis vicieux là, mais vu que j'ai du mal à comprendre le "-e '/;[ ]*\/\*/{:z; N; s!/\*.*\*/!!;Tz}'" ...

A+
Christophe

Avec ça ça devrait le faire à tous les coups :

sed -e 's!/\*.*\*/!!' -e '/.*\/\*/{:z; N; s!/\*.*\*/!!;Tz}' -e'/\/\*/,/\*\//d' plop

Pour les explications, ce soir quand je rentre...

;-))

merci !! Ca m'a l'air de bien marcher !!

pour ceux que ca interesse, le filtre qui supprime donc les commentaires dans un fichier C, qu'ils soient de type /* comment */ , // comment , sur une ou plusieurs lignes .... :


sed -e 's!/\*.*\*/!!
/.*\/\*/{:z; N; s!/\*.*\*/!!;Tz}
s/\/\/.*//g
/\/\*/,/\*\//d
'

Voilà les explications des différentes parties juste pour la forme, parce qu'avec les nouvelles directives, la simple expression :

sed -e '/.*\/\*/{:z; N; s!/\*.*\*/!!;Tz}'

suffit pour tous les cas ;-))

En fait on recherche un motif correspondant à "/*bla ... bla... bla ... */" d'abord sur une ligne entière (les délimiteurs commençant et finissant la ligne), puis on examine le cas ou le 1er délimiteur ne serait pas le 1 er caractère sur la ligne et que le délimiteur de fin ne serait pas sur la même ligne. En dernier lieu vient le cas où les commentaires sont sur plusieurs ligne avec un délimiteur de départ en début de ligne...

 s!/\*.*\*/!!            
# sur une ligne on supprime tout

/.*\/\*/ {           
# sur plusieurs lignes ( matche aussi le cas sur un seule ligne) mais ne commençant pas en début de ligne. Si une ligne comprenant le motif est trouvée on enchaine les commandes se trouvant entre accolades

    :z                  
# définition d'une étiquette pour boucler

    N                   
# donc si un motif est trouvé,  on ajoute la ligne suivante dans l'espace de travail

    s!/\*.*\*/!!       
 # on supprime tout entre /* et */ si le motif est présent

    T z                
 # on teste si une substitution a eu lieu au cas ou le motif serait présent dans l'espace de travail. Dans le cas contraire on boucle en se branchant à l'étiquette et ainsi de suite jusqu'à ce qu'une substitution ait lieu, ce qui aura pour effet de lancer la commande qui suit l'accolade fermante
}

/\/\*/,/\*\// d         
#si un motif correspondant se situe sur plusieurs lignes, on efface toutes les lignes de cet intervalle

PS. le motif :

/;*[ ]*\/\*/

correspondait à :
un motif ne commençant pas en début de ligne, après un point virgule suivi éventuellement d'un (ou plusieurs) espace(s)...

;-))

Allez un ch'tit dernier pour la route et pour que ce soit bien propre (le dernier laisser plein de lignes vides inutiles).

Le fichier de départ :

$ cat plop
toto=0;

/* ======================
blabla
blabla
blabla
=======================*/

toto=1; /* commentaire
blabla
blabla
blabla
sur plusieurs lignes */

#define ONE 1 /* ceci est un commentaire sur
plusieurs lignes */

toto=2;
/* comment */
toto=3;

La version sale :

$ sed -e '/.*\/\*/{:z; N; s!/\*.*\*/!!;Tz}' plop
toto=0;



toto=1;

#define ONE 1

toto=2;

toto=3;

Et la version proprette :

$ sed -e '/.*\/\*/{:z; N; s!/\*.*\*/!!;Tz; /^$/{N;/^\n$/d}}' plop
toto=0;

toto=1;

#define ONE 1

toto=2;

toto=3;

;-))

Merci pour ces explications limpides ! ;-)
ca marche du tonnerre de Brest !
A+