Probleme sur code vba export [Résolu/Fermé]

cedric0715 199 Messages postés mercredi 25 février 2015Date d'inscription 5 décembre 2017 Dernière intervention - 25 nov. 2016 à 11:52 - Dernière réponse : f894009 12541 Messages postés dimanche 25 novembre 2007Date d'inscription 11 décembre 2017 Dernière intervention
- 25 nov. 2016 à 12:07
Bonjour,

mon code fonctionne mais d' es qu'il est utiliser par une autre personne sur un autre poste le code Open "D:\CBREDECHE\Bureau\testexcel.csv" For Output As #1 'a changer pour les autre pc'
ne fonctionne pas ,que faut il que je mette pour que n'importe quel personne qui utilise le fichier puisse enregistre export ou il veux "fenêtre de commande enregistrement"

trouvez ci dessous mon code
merci par avance

  Sub ExportCSV()

Dim LigneCSV As String
Dim PlageCSV As Range
Dim Ligne As Integer, Colonne As Integer, Nb_Ligne As Integer, Nb_Colonne As Integer


'Fermeture ficher si ouvert
Close

'Plage CSV
Set PlageCSV = Worksheets("Donné équipement").Range("A1:T650")

'Ouverture du fichier de sortie
Open "D:\CBREDECHE\Bureau\testexcel.csv" For Output As #1 'a changer pour les autre pc'

'Butees de comptage
Nb_Ligne = PlageCSV.Rows.Count
Nb_Colonne = PlageCSV.Columns.Count

'Boucle sur la plage et ajoute les lignes au fichier
For Ligne = 1 To Nb_Ligne
For Colonne = 1 To Nb_Colonne
If LigneCSV <> "" Then
LigneCSV = LigneCSV & ";"
End If
'construction ligne
LigneCSV = LigneCSV & PlageCSV.Cells(Ligne, Colonne).Value
Next Colonne
'Enregistrement ligne
Print #1, LigneCSV
LigneCSV = ""
Next Ligne

'Fermeture du fichier
Close #1

End Sub

Afficher la suite 
199Messages postés mercredi 25 février 2015Date d'inscription 5 décembre 2017 Dernière intervention

1 réponse

f894009 12541 Messages postés dimanche 25 novembre 2007Date d'inscription 11 décembre 2017 Dernière intervention - 25 nov. 2016 à 12:07
0
Utile
Bonjour,

Sub ExportCSV()
    Dim LigneCSV As String
    Dim PlageCSV As Range
    Dim Ligne As Integer, Colonne As Integer, Nb_Ligne As Integer, Nb_Colonne As Integer
    
    'choix du repertoire
    Dim Repertoire As FileDialog, Rep As String
    
    Set Repertoire = Application.FileDialog(msoFileDialogFolderPicker)
    Repertoire.Show
    If Repertoire.SelectedItems.Count > 0 Then
        Rep = Repertoire.SelectedItems(1) & "\"
        'Fermeture ficher si ouvert
        Close
        'Plage CSV
        Set PlageCSV = Worksheets("Donné équipement").Range("A1:T650")
        'Ouverture du fichier de sortie
        Open Rep & "testexcel.csv" For Output As #1 'a changer pour les autre pc'
        'Butees de comptage
        Nb_Ligne = PlageCSV.Rows.Count
        Nb_Colonne = PlageCSV.Columns.Count
        'Boucle sur la plage et ajoute les lignes au fichier
        For Ligne = 1 To Nb_Ligne
            For Colonne = 1 To Nb_Colonne
                If LigneCSV <> "" Then
                    LigneCSV = LigneCSV & ";"
                End If
                'construction ligne
             LigneCSV = LigneCSV & PlageCSV.Cells(Ligne, Colonne).Value
            Next Colonne
            'Enregistrement ligne
            Print #1, LigneCSV
            LigneCSV = ""
        Next Ligne
        'Fermeture du fichier
        Close #1
    Else
        MsgBox "Choisissez un repertoire!!!!"
    End If

End Sub