Fonction SPLIT

Résolu/Fermé

Excel

Nico - Modifié par pijaku le 26/08/2016 à 13:37
pijaku Messages postés 12263 Date d'inscription jeudi 15 mai 2008 Statut Modérateur Dernière intervention 4 janvier 2024 - 26 août 2016 à 14:55

Bonjour,

J'ai n cellules dans une colonne. Les n cellules contiennent de 1 à n lignes.
Je souhaite dissocier ces lignes dans une autre colonne.

La macro fonctionne si je définie une cellule (ex. B1). En revanche pour une plage, j'ai toujours une erreur.

Ci-dessous la macro en question :

Sub decoupe2()
Dim s As Variant, i As Byte
s = Split(Range("B" & Rows.Count), Chr(10))
For i = 0 To UBound(s)
    Cells(i + 1, 3).Value = s(i)
Next i
End Sub

Merci de votre aide !

A voir également:

Fonction split excel francais
Tubidy rap francais - Forum Musique / Radio / Clip
Lire le coran en français pdf - Télécharger - Histoire & Religion
Wetransfer français - Télécharger - Téléchargement & Transfert
Liste déroulante excel - Guide
Excel fonction si et - Guide

4 réponses

Réponse 1 / 4

pijaku Messages postés 12263 Date d'inscription jeudi 15 mai 2008 Statut Modérateur Dernière intervention 4 janvier 2024 2 743
26 août 2016 à 13:41

Bonjour,

Avec restitution à partir de la colonne C :

Dim DL As Long, Lig As Long, Col As Integer, s As Variant, i As Byte
DL = Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row 
Col = 3
For Lig = 1 To DL
    If Instr(Range("B" & Lig), Chr(10)) > 0 Then
        s = Split(Range("B" & Lig), Chr(10))
        For i = 0 To UBound(s)
            Cells(i + 1, Col).Value = s(i)
        Next i
        Col = Col + 1
    End If
Next Lig

Code non testé, écrit "à l'arrache"...

Nico
26 août 2016 à 14:22

Merci pour ta réponse pijaku, la macro fonctionne parfaitement !
Est-il possible de mettre le contenu des lignes l'une à la suite des autres et non en changeant de colonne ?

pijaku Messages postés 12263 Date d'inscription jeudi 15 mai 2008 Statut Modérateur Dernière intervention 4 janvier 2024 2 743 > Nico
26 août 2016 à 14:24

Oui.
Regarde la solution de Thev (salutations au passage).

Réponse 2 / 4

thev Messages postés 1851 Date d'inscription lundi 7 avril 2008 Statut Membre Dernière intervention 15 avril 2024 681
Modifié par thev le 26/08/2016 à 14:21

Bonjour,

ci-dessous autre solution à partir de la colonne C


Sub dissocier()
    
    Dim xl As Excel.Application
    Dim cellule As Range
    Dim nb_lignes As Integer, i As Long
    Dim s() As String
    
    Set xl = Application
    For Each cellule In Columns("B").SpecialCells(xlCellTypeConstants)
        s = Split(cellule, Chr(10))
        nb_lignes = UBound(s) + 1
        i = cellule.Row         ' numéro de ligne de la plage
        Cells(i, "C").Resize(, 2).Value = xl.Transpose(xl.Transpose(s))
    Next cellule

End Sub

Nico
26 août 2016 à 14:28

Merci Thev pour ton retour.
Lorsque je lance la macro, j'ai une erreur sur le point suivant

Cells(i, "C").Resize(, 2).Value = xl.Transpose(xl.Transpose(s))

Réponse 4 / 4

pijaku Messages postés 12263 Date d'inscription jeudi 15 mai 2008 Statut Modérateur Dernière intervention 4 janvier 2024 2 743
26 août 2016 à 14:40

Petite modif ddu code de Thev (au cas ou il y a dans une même cellule 2 passages à la ligne) :

Sub dissocier()
    
    Dim xl As Excel.Application
    Dim cellule As Range
    Dim nb_lignes As Integer, i As Long
    Dim s() As String
    
    Set xl = Application
    For Each cellule In Columns("B").SpecialCells(xlCellTypeConstants)
        s = Split(cellule, Chr(10))
        nb_lignes = UBound(s) + 1
        i = cellule.Row         ' numéro de ligne de la plage
        Cells(i, "C").Resize(, UBound(s) + 1).Value = xl.Transpose(xl.Transpose(s))
    Next cellule
End Sub

Et avec les données à la suite en colonne C :

Sub MachinTruc()
Dim DL As Long, DLB As Long, Lig As Long, s As Variant, i As Byte

DL = Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row
DLB = 2 ' ==> 1ère ligne de restitution colonne C

For Lig = 1 To DL
    If InStr(Range("B" & Lig), Chr(10)) > 0 Then
        s = Split(Range("B" & Lig), Chr(10))
        For i = 0 To UBound(s)
            Cells(DLB, 3).Value = s(i)
            DLB = DLB + 1
        Next i
    Else
        Cells(DLB, 3).Value = Cells(Lig, 2)
        DLB = DLB + 1
    End If
Next Lig
End Sub

thev Messages postés 1851 Date d'inscription lundi 7 avril 2008 Statut Membre Dernière intervention 15 avril 2024 681
26 août 2016 à 14:50

modif de mon code OK.
Cela dit, mon code met bien les données à la suite, de la colonne C à la colonne C+n

pijaku Messages postés 12263 Date d'inscription jeudi 15 mai 2008 Statut Modérateur Dernière intervention 4 janvier 2024 2 743 > thev Messages postés 1851 Date d'inscription lundi 7 avril 2008 Statut Membre Dernière intervention 15 avril 2024
26 août 2016 à 14:55

Cela dit, mon code met bien les données à la suite, de la colonne C à la colonne C+n
Oui thev.
J'ai bien vu ça...

A++

Nico
26 août 2016 à 14:52

Vous êtes au top !
Merci les gars

Discussions similaires

Activer la fonction DATEDIF sur Excel 2016

Transformer un chiffre en lettres dans excel sans macro

EXCEL transformer chiffres en lettre -facture

convertir un chiffre en lettre avec excel

Sous totaux avec conditions

Ecrire une valeur dans une cellule en fonction d'une autre

Discussions similaires

Newsletters