Macro de cellule vide

essaye ce code :

Option Explicit

Sub FillBlanks()
Dim rRange1 As Range, rRange2 As Range
Dim lReply As Integer

If Selection.Cells.Count = 1 Then
'MsgBox "You must select your list and include the blank cells", _
vbInformation, "OzGrid.com"
MsgBox "Votre liste doit inclure les cellules vides.", _
vbInformation, "CSI Nantes - RT"
Exit Sub
ElseIf Selection.Columns.Count > 1 Then
'MsgBox "You must select only one column", _
vbInformation, "OzGrid.com"
MsgBox "Sélectionner une seule colonne.", _
vbInformation, "CSI Nantes - RT"
Exit Sub
End If

Set rRange1 = Selection
On Error Resume Next
Set rRange2 = rRange1.SpecialCells(xlCellTypeBlanks)
On Error GoTo 0

If rRange2 Is Nothing Then
'MsgBox "No blank cells Found", _
vbInformation, "OzGrid.com"
MsgBox "Votre sélection ne comporte aucune cellule vide.", _
vbInformation, "CSI Nantes - RT"
Exit Sub
End If

rRange2.FormulaR1C1 = "=R[-1]C"
'lReply = MsgBox("Convert to Values", vbYesNo + vbQuestion, "OzGrid.com")
lReply = MsgBox("Convertir en Valeur", vbYesNo + vbQuestion, "Acceper de convertir ?")
If lReply = vbYes Then rRange1 = rRange1.Value
End Sub

L'idéal est de l'affecter à un bouton.
Tu sélectionne ta plage et tu clique sur le bouton .. ;)